Add regression test for GStreamer introspection issue

test cases/frameworks/38 gir both_libraries/bar.c

@@ -0,0 +1,8 @@
+#include "bar.h"
+
+int foo_func(void);
+
+int bar_func(void)
+{
+    return foo_func() + 42;
+}

test cases/frameworks/38 gir both_libraries/bar.h

@@ -0,0 +1 @@
+int bar_func(void);

test cases/frameworks/38 gir both_libraries/foo.c

@@ -0,0 +1,6 @@
+#include "foo.h"
+
+int foo_func(void)
+{
+    return 42;
+}

test cases/frameworks/38 gir both_libraries/foo.h

@@ -0,0 +1 @@
+int foo_func(void);

test cases/frameworks/38 gir both_libraries/meson.build

@@ -0,0 +1,37 @@
+project('gir both libraries', 'c')
+
+gir = dependency('gobject-introspection-1.0', required: false)
+if not gir.found()
+  error('MESON_SKIP_TEST gobject-introspection not found.')
+endif
+
+gnome = import('gnome')
+
+# Regression test simulating how GStreamer generate its GIRs.
+# Generated gobject-introspection binaries for every GStreamer libraries must
+# first call gst_init() defined in the main libgstreamer, which means they need
+# to link on that lib.
+# A regression caused by https://github.com/mesonbuild/meson/pull/12632 made
+# Meson not link the binary generated for bar with libfoo in the case it uses
+# both_libraries().
+
+libfoo = both_libraries('foo', 'foo.c')
+foo_gir = gnome.generate_gir(libfoo,
+  namespace: 'foo',
+  nsversion: '1.0',
+  sources: ['foo.c', 'foo.h'],
+)
+foo_dep = declare_dependency(
+  link_with: libfoo,
+  #link_with: libfoo.get_shared_lib(),
+  sources: foo_gir,
+)
+
+libbar = both_libraries('bar', 'bar.c', dependencies: foo_dep)
+gnome.generate_gir(libbar,
+  namespace: 'bar',
+  nsversion: '1.0',
+  sources: ['bar.c', 'bar.h'],
+  extra_args: '--add-init-section=extern void foo_func(void);foo_func();',
+  dependencies: foo_dep,
+)