From 5eb0ae3e9c615b34684fa78834d3ec45c314e0f8 Mon Sep 17 00:00:00 2001
From: actionless <actionless.loveless@gmail.com>
Date: Tue, 17 Mar 2020 19:58:08 +0100
Subject: [PATCH] chore(packaging: arch): prepare PKGBUILD for suru++ icons
 plugin (re: #129)

---
 packaging/arch/PKGBUILD_gui            |  1 +
 packaging/arch/PKGBUILD_icons_suruplus | 62 ++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 packaging/arch/PKGBUILD_icons_suruplus

diff --git a/packaging/arch/PKGBUILD_gui b/packaging/arch/PKGBUILD_gui
index 813620e3e..626e9dfd4 100644
--- a/packaging/arch/PKGBUILD_gui
+++ b/packaging/arch/PKGBUILD_gui
@@ -35,6 +35,7 @@ optdepends=(
 	'themix-icons-archdroid: Icons Style plugin'
 	'themix-icons-gnome-colors: Icons Style plugin'
 	'themix-icons-papirus: Icons Style plugin'
+	'themix-icons-suru-plus: Icons Style plugin'
 
 	'xorg-xrdb: for the `xresources` theme'
 )
diff --git a/packaging/arch/PKGBUILD_icons_suruplus b/packaging/arch/PKGBUILD_icons_suruplus
new file mode 100644
index 000000000..c46579df6
--- /dev/null
+++ b/packaging/arch/PKGBUILD_icons_suruplus
@@ -0,0 +1,62 @@
+# Maintainer: Yauhen Kirylau <actionless DOT loveless PLUS aur AT gmail MF com>
+# Upstream URL: https://github.com/gusbemacbe/suru-plus/
+
+_pkgname=themix-icons-suru-plus
+_reponame=suru-plus
+pkgname="${_pkgname}-git"
+pkgver=v30.0.r2.g9bd895f32
+pkgrel=1
+pkgdesc="Suru++ icons plugin for Themix GUI designer"
+arch=('x86_64' 'i686')
+url="https://github.com/gusbemacbe/suru-plus/"
+license=('GPL3')
+source=(
+	"git+https://github.com/themix-project/oomox.git#branch=master"
+	"${_reponame}::git+https://github.com/gusbemacbe/suru-plus.git#branch=master"
+)
+md5sums=('SKIP'
+         'SKIP')
+depends=(
+	'sed'
+    'findutils'
+)
+makedepends=(
+	'git'
+	'python'
+)
+optdepends=(
+	'themix-gui: GUI'
+    'yaru-icon-theme: fallback icons'
+    'gnome-icon-theme: fallback icons'
+    'gnome-icon-theme-symbolic: fallback icons'
+)
+options=(
+	'!strip'
+)
+provides=($_pkgname)
+conflicts=($_pkgname)
+
+pkgver() {
+	cd "${srcdir}/${_reponame}"
+	git describe --tags --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package() {
+	_oomox_dir=/opt/oomox
+	_plugin_name=icons_suruplus
+	_plugin_subpath="/${_reponame}"
+
+	pkg_tmp_dir="${pkgdir}/_tmp"
+	rm -fr "$pkg_tmp_dir"
+	cp -r "${srcdir}/oomox" "$pkg_tmp_dir"
+	rm -rf "${pkg_tmp_dir}/plugins/${_plugin_name}${_plugin_subpath}"
+	cp -r "${srcdir}/${_reponame}" "${pkg_tmp_dir}/plugins/${_plugin_name}${_plugin_subpath}"
+
+	cd "$pkg_tmp_dir"
+	make DESTDIR="${pkgdir}" APPDIR="${_oomox_dir}" PREFIX="/usr" "install_${_plugin_name}"
+	rm -fr "$pkg_tmp_dir"
+
+	python -O -m compileall "${pkgdir}${_oomox_dir}/plugins/${_plugin_name}" -d "${_oomox_dir}/plugins/${_plugin_name}"
+}
+
+# vim: ft=PKGBUILD