build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '1.0.15'
}

abstract class TeaConDumpPathToGitHub extends DefaultTask {
    @Input
    abstract Property<String> getPublishName()
    @InputFile
    abstract RegularFileProperty getTargetFile()
    @TaskAction
    void dump() {
        if (System.env.GITHUB_ACTIONS) {
            File theFile = targetFile.getAsFile().get()

            def outputFile = new File(System.env.GITHUB_OUTPUT)
            // Use the env-specific line separator for maximally possible compatibility
            def newLine = System.getProperty('line.separator')

            // Write out new env variable for later usage
            outputFile << newLine << "artifact_name=${theFile.getName()}"
            outputFile << newLine << "artifact_publish_name=${publishName.get()}"
            outputFile << newLine << "artifact_path=${theFile.absolutePath}"
        }
    }
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}

version = mod_version
group = mod_group_id

repositories {
    mavenLocal()
}

base {
    archivesName = mod_id
}

// Mojang ships Java 21 to end users starting in 1.20.5, so mods should target Java 21.
java.toolchain.languageVersion = JavaLanguageVersion.of(21)

neoForge {
    // Specify the version of NeoForge to use.
    version = project.neo_version

    accessTransformers {
        file('src/main/resources/META-INF/accesstransformer.cfg')
    }

    parchment {
        mappingsVersion = project.parchment_mappings_version
        minecraftVersion = project.parchment_minecraft_version
    }

    // This line is optional. Access Transformers are automatically detected
    // accessTransformers = project.files('src/main/resources/META-INF/accesstransformer.cfg')

    // Default run configurations.
    // These can be tweaked, removed, or duplicated as needed.
    runs {
        client {
            client()

            // Comma-separated list of namespaces to load gametests from. Empty = all namespaces.
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        server {
            server()
            programArgument '--nogui'
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        // This run config launches GameTestServer and runs all registered gametests, then exits.
        // By default, the server will crash when no gametests are provided.
        // The gametest system is also enabled by default for other run configs under the /test command.
        gameTestServer {
            type = "gameTestServer"
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        data {
            data()

            // example of overriding the workingDirectory set in configureEach above, uncomment if you want to use it
            // gameDirectory = project.file('run-data')

            // Specify the modid for data generation, where to output the resulting resource, and where to look for existing resources.
            programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
        }

        // applies to all the run configs above
        configureEach {
            // Recommended logging data for a userdev environment
            // The markers can be added/remove as needed separated by commas.
            // "SCAN": For mods scan.
            // "REGISTRIES": For firing of registry events.
            // "REGISTRYDUMP": For getting the contents of all registries.
            systemProperty 'forge.logging.markers', 'REGISTRIES'

            // Recommended logging level for the console
            // You can set various levels here.
            // Please read: https://stackoverflow.com/questions/2031163/when-to-use-the-different-log-levels
            logLevel = org.slf4j.event.Level.DEBUG
        }
    }

    mods {
        // define mod <-> source bindings
        // these are used to tell the game which sources are for which mod
        // mostly optional in a single mod project
        // but multi mod projects should define one per mod
        "${mod_id}" {
            sourceSet(sourceSets.main)
        }
    }
}

// Include resources generated by data generators.
sourceSets.main.resources { srcDir 'src/generated/resources' }

// Sets up a dependency configuration called 'localRuntime'.
// This configuration should be used instead of 'runtimeOnly' to declare
// a dependency that will be present for runtime testing but that is
// "optional", meaning it will not be pulled by dependents of this mod.
configurations {
    runtimeClasspath.extendsFrom localRuntime
}

repositories {
    maven {
        name = "Curse maven"
        url = "https://cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
    maven {
        // location of the maven that hosts JEI files since January 2023
        name = "Jared's maven"
        url = "https://maven.blamejared.com/"
    }
    maven {
        // location of a maven mirror for JEI files, as a fallback
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
}

dependencies {
    localRuntime "mezz.jei:jei-1.21-neoforge:${jei_version}"

    implementation "curse.maven:the-one-probe-245211:5502323"
}

// This block of code expands all declared replace properties in the specified resource targets.
// A missing property will result in an error. Properties are expanded using ${} Groovy notation.
// When "copyIdeResources" is enabled, this will also run before the game launches in IDE environments.
// See https://docs.gradle.org/current/dsl/org.gradle.language.jvm.tasks.ProcessResources.html
tasks.withType(ProcessResources).configureEach {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            neo_version_range      : neo_version_range,
            loader_version_range   : loader_version_range,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
            mod_authors            : mod_authors,
            mod_description        : mod_description
    ]
    inputs.properties replaceProperties

    filesMatching(['META-INF/neoforge.mods.toml']) {
        expand replaceProperties
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

// IDEA no longer automatically downloads sources/javadoc jars for dependencies, so we need to explicitly enable the behavior.
idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}

publishing { PublishingExtension it ->
    publications {
        // noinspection GroovyAssignabilityCheck
        release(MavenPublication) {
            // noinspection GroovyAssignabilityCheck
            from components.java
            // noinspection GroovyAssignabilityCheck
            groupId = "org.teacon"
            // noinspection GroovyAssignabilityCheck
            artifactId = 'PowerTool-NeoForge-1.21'
            // noinspection GroovyAssignabilityCheck
            version = mod_version
            pom {
                // noinspection GroovyAssignabilityCheck
                name = 'PowerTool'
                // noinspection GroovyAssignabilityCheck
                url = "https://github.com/teaconmc/PowerTool"
                licenses {
                    license {
                        // noinspection GroovyAssignabilityCheck
                        name = 'GPLv3'
                        // noinspection GroovyAssignabilityCheck
                        url = "https://github.com/teaconmc/PowerTool/blob/1.21-neoforge/LICENSE"
                    }
                }
                organization {
                    // noinspection GroovyAssignabilityCheck
                    name = 'TeaConMC'
                    // noinspection GroovyAssignabilityCheck
                    url = 'https://github.com/teaconmc'
                }
                developers {
                    developer {
                        id = '3TUSK'
                        name = '3TUSK'
                    }
                    developer {
                        id = 'xkball'
                        name = 'xkball'
                    }
                }
                issueManagement {
                    // noinspection GroovyAssignabilityCheck
                    system = 'GitHub Issues'
                    // noinspection GroovyAssignabilityCheck
                    url = "https://github.com/teaconmc/PowerTool/issues"
                }
                scm {
                    // noinspection GroovyAssignabilityCheck
                    url = "https://github.com/teaconmc/PowerTool"
                    // noinspection GroovyAssignabilityCheck
                    connection = "scm:git:git://github.com/teaconmc/PowerTool.git"
                    // noinspection GroovyAssignabilityCheck
                    developerConnection = "scm:git:git@github.com:teaconmc/PowerTool.git"
                }
            }
        }
    }
    repositories {
        maven {
            name = "teacon"
            url = "s3://maven/"
            credentials(AwsCredentials) {
                accessKey = System.env.ARCHIVE_ACCESS_KEY
                secretKey = System.env.ARCHIVE_SECRET_KEY
            }
        }
    }
}

tasks.withType(PublishToMavenRepository).configureEach {
    if (repository && repository.name == "teacon") {
        it.onlyIf {
            System.env.ARCHIVE_ACCESS_KEY && System.env.ARCHIVE_SECRET_KEY
        }
    }
}

tasks.register("githubActionOutput", TeaConDumpPathToGitHub) { task ->
    task.onlyIf {
        System.env.GITHUB_ACTIONS
    }
    task.getPublishName().set("${jar.archiveBaseName.get()}-${version}.jar")
    task.getTargetFile().set(jar.archiveFile)
}