build.gradle

plugins {
    id 'eclipse'
    id 'maven-publish'
    id 'net.minecraftforge.gradle' version '[6.0,6.2)'
}

version = '1.0.2'
group = 'org.teacon'
archivesBaseName = 'CommandConfirm-Forge-1.20.1'

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

minecraft {
    mappings channel: 'official', version: '1.20.1'

//    accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg')

    runs {
        client {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            property 'forge.enabledGameTestNamespaces', 'blist'
            mods {
                blist {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            property 'forge.enabledGameTestNamespaces', 'blist'

            mods {
                blist {
                    source sourceSets.main
                }
            }
        }

        gameTestServer {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            property 'forge.enabledGameTestNamespaces', 'blist'
            mods {
                blist {
                    source sourceSets.main
                }
            }
        }

        data {
            workingDirectory project.file('run')
            property 'forge.logging.markers', 'REGISTRIES'
            property 'forge.logging.console.level', 'debug'
            args '--mod', 'blist', '--all', '--output', file('src/generated/resources/'), '--existing', file('src/main/resources/')
            mods {
                blist {
                    source sourceSets.main
                }
            }
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    // Put repositories for dependencies here
    // ForgeGradle automatically adds the Forge maven and Maven Central for you

    // If you have mod jar dependencies in ./libs, you can declare them as a repository like so:
    // flatDir {
    //     dir 'libs'
    // }

}

dependencies {
    minecraft 'net.minecraftforge:forge:1.20.1-47.0.1'
}

// Example for how to get properties into the manifest for reading at runtime.
jar {
    manifest {
        attributes([
                "Specification-Title"     : "CommandConfirm-Forge-1.20.1",
                "Specification-Vendor"    : "TeaConMC",
                "Specification-Version"   : "1", // We are version 1 of ourselves
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "TeaConMC",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
        ])
    }
}

tasks.register('devJar', Jar) {
    archiveClassifier = "dev"
    dependsOn classes
    from {
        sourceSets.main.output
    }
}

tasks.register('srcJar', Jar) {
    archiveClassifier = "src"
    from {
        sourceSets.main.allSource
    }
}

jar.finalizedBy('reobfJar')
// However if you are in a multi-project build, dev time needs unobfed jar files, so you can delay the obfuscation until publishing by doing
// publish.dependsOn('reobfJar')

artifacts {
    archives devJar
    archives srcJar
}

publishing {
    publications {
        release(MavenPublication) {
            artifactId = archivesBaseName

            artifact jar
            artifact srcJar
            artifact devJar

            pom {
                name = 'CommandConfirm Forge 1.20.1'
                description = 'Require extra confirmation before executing commands infecting large amount of entities.'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://opensource.org/license/mit/'
                    }
                }
                developers {
                    developer {
                        id = 'Seraph_JACK'
                        name = 'Seraph_JACK'
                    }
                }
            }
        }
    }
    repositories {
        maven {
            name = "TeaConOSS"
            url = "s3://maven/"
            credentials(AwsCredentials) {
                accessKey = System.env.TEACON_ARCHIVE_ACCESS_KEY
                secretKey = System.env.TEACON_ARCHIVE_ACCESS_SECRET
            }
        }
        maven {
            name = "TeaConGitea"
            url = "https://git.teacon.cn/api/packages/teaconmc/maven"

            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "token " + System.getenv("GITEA_TOKEN")
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}