build.gradle

apply plugin: 'run.smt.dependency-properties'

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()

        maven { url 'https://plugins.gradle.org/m2/' }
    }
    dependencies {
        classpath 'io.spring.gradle:dependency-management-plugin:1.0.1.RELEASE'
        classpath 'run.smt.gradle.plugins:dependency-properties-plugin:1.0.0'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlinVersion}"
    }
}

def leafProjects = subprojects.findAll { it.projectDir.toPath().resolve("build.gradle").toFile().exists() }

configure(leafProjects.findAll { !(it.name in [project(':ktest-pom'), project(':doc-test')].collect { it.name }) }) {
    apply plugin: 'kotlin'
    apply plugin: 'maven'
    apply plugin: 'io.spring.dependency-management'
    apply from: "${rootDir}/dependencies.gradle"
    apply from: "${rootDir}/gradle/ossrh.gradle"
    apply from: "${rootDir}/gradle/ossrh-default-pom.gradle"

    repositories {
        mavenLocal()
        mavenCentral()
    }

    compileKotlin {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }

    compileTestKotlin {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }

    task javadocJar(type: Jar) {
        classifier = 'javadoc'
        from javadoc
    }

    task sourcesJar(type: Jar) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    artifacts {
        archives javadocJar, sourcesJar
    }
}