21_Digital_Clock.bc2

1000 A=700:GOTO20:REM DIGITALE KLOK
1010 GOSUB100
1020 DIMA$(6),B$(9,6),CR$(7),JJ(9)
1030 FORI=1 TO6:READA$(I):NEXTI
1040 FORI=0 TO7:READCR$(I):NEXTI
1050 FORI=1 TO9:READJJ(I):NEXTI
1060 PRINT"     D I G I T A L E   K L O K":PRINT
1070 PRINT"Het volgende programma is afkomstig van"
1080 PRINT:PRINT"een  D A I  personal computer"
1090 PRINT:PRINT"Dit programma is bedoeld als demo-"
1100 PRINT:PRINT"programma voor   NOS BASICODE-2"
1110 PRINT:PRINT:PRINT:PRINT
1120 PRINT:PRINT"    DRUK OP EEN TOETS";:GOSUB210
1130 GOSUB100
1140 PRINT"Tijdvertraging proefondervindelijk vast"
1150 PRINT:PRINT"te stellen."
1160 PRINT
1170 PRINT"Tijdvertraging (0-5000)";:INPUTT:PRINT
1180 PRINT"Aantal seconden per stap (4-60) ";:INPUTC
1190 E$=" "
1200 PRINT:PRINT"Voer nu svp de tijd in:"
1210 PRINT:PRINT"                  uren ";:INPUTU
1220 PRINT:PRINT"               minuten ";:INPUTM
1230 PRINT:PRINT"              seconden ";:INPUTS
1240 GOSUB100
1250 N=INT(U/10):J=1:IFN=0 THEN1270
1260 GOSUB1440
1270 N=U-N*10:J=2:GOSUB1440
1280 N=INT(M/10):J=3:GOSUB1440
1290 N=M-N*10:J=4:GOSUB1440
1300 N=INT(S/10):J=5:GOSUB1440
1310 N=S-N*10:J=6:GOSUB1440
1320 HO=0:VE=4:GOSUB110
1330 FORI=1 TO9
1340 J=JJ(I):K=I:IFI>5 THENK=6
1350 PRINTE$;B$(J,1);E$;B$(J,2);E$;E$;B$(J,3);
1360 PRINTE$;B$(J,4);E$;E$;B$(K,5);E$;B$(K,6)
1370 NEXTI
1380 FORI=1 TOT:NEXTI
1390 S=S+C:IFS<60 THEN1250
1400 S=S-60:M=M+1:IFM<60 THEN1250
1410 M=M-60:U=U+1:IFU<24 THEN1250
1420 U=0
1430 FORI=1 TO9:B$(I,1)="     ":NEXTI:GOTO1250
1440 FORI=1 TO5
1450 B$(I,J)=CR$(VAL(MID$(A$(I),N+1,1)))
1460 NEXTI
1470 RETURN
25000 DATA"7277574777","5211544155","5277777377"
25010 DATA"5241115151","7277177177","0000000000"
25020 DATA"     ","    X","  X  ","   XX"
25030 DATA"X    ","X   X","x","XXXXX"
25040 DATA 1,2,2,2,3,4,4,4,5
30000 REM"auteur: TH.V.LIESHOUT"
30010 REM"        POSTGALEI 5"
30020 REM"        1687 VP WOGNUM (N.H.)"