gbk2fna

#! /usr/bin/env perl

use strict;
use warnings FATAL => 'all';
use Carp::Always;

# use FindBin;
# use lib "$FindBin::Bin";
# use Xyzzy;

use constant { TRUE => 1, FALSE => 0 };

# ------------------------------------------------------------------------
# Process the command line
# ------------------------------------------------------------------------

use File::Basename;
use Getopt::Std;

our $opt_h;
our $opt_n;

sub usage {
  my $progname = basename($0);
  print STDERR "Usage: $progname [options] < genome.gbk > sequences.fna\n";
  print STDERR "-n NAME - Use NAME as locus name for a single sequence\n";
  print STDERR "-h - print help\n";
  exit(@_);
}

my $stat = getopts('hn:');
if (!$stat) {
  usage(1);
}
if ($opt_h) {
  usage();
}
if (scalar(@ARGV) != 0) {
  usage(1);
}

# ------------------------------------------------------------------------

my $count = 0;
my $locus;
my $printing = 0;
while ( <STDIN> ) {
  chomp;
  if ( $_ =~ "^//" ) {
    $printing = 0;
    $locus = undef;
  } elsif ( $printing ) {
    $_ =~ s/^ +[0-9]+//;
    $_ =~ s/[ \t]+//g;
    print $_,"\n";
  } elsif ( $_ =~ /^LOCUS +([^ ]+)/ ) {
    $count++;
    $locus = $1;
  } elsif ( $_ =~ /^ORIGIN/ ) {
    if ($opt_n) {
      if ($count > 1) {
	die "More than one sequence found,";
      }
      print ">$opt_n\n"
    } else {
      print ">$locus\n";
    }
    $printing = 1;
  }
}