Esp32 A2DP giving errors

[RobotSquad]

for the following code:
`#include "BluetoothA2DPSource.h"
#include <SPI.h>
#include <SD.h>
#define LOG_LOCAL_LEVEL ESP_LOG_VERBOSE
#include "esp_log.h"
static const char* TAG = "A2DP_DF";
BluetoothA2DPSource a2dp_source;
File sound_file;
const char* file_name = "/audio.raw";
const int sd_ss_pin = 13;
const int frame_size_bytes = sizeof(int16_t) * 2;
// callback used by A2DP to provide the sound data
int32_t get_sound_data(Frame frame, int32_t len) {
// the data in the file must be in int16 with 2 channels
size_t result_len_bytes = sound_file.read((uint8_t)frame, len * frame_size_bytes );
// result is in number of frames
int32_t result_len = result_len_bytes / frame_size_bytes;
ESP_LOGD("get_sound_data", "%d -> %d",len, result_len);
return result_len;
}

// Arduino Setup
void setup(void) {
Serial.begin(115200);
SPI.begin(14, 2, 15, 13);
// Setup SD and open file
if(SD.begin(13)){
Serial.println("SD OPEN");
sound_file = SD.open(file_name, FILE_READ);
// start the bluetooth
Serial.println("starting A2DP...");
a2dp_source.start("Infinity Glide 510", get_sound_data);
}
}

// Arduino loop - repeated processing
void loop() {
}`
I am getting errors while running it on esp32 cam as after playing a few lines of the song, it gives the following error:
"Task watchdog got triggered. The following tasks did not reset the watchdog in time"
please help

[pschatzmann]

Not sure if it helps, by did you try to add a delay into the empty loop?

[RobotSquad]

isnt all the code in void setup so that it doesnt repeat itself continuously?

[pschatzmann]

yes, but I noticed that an empty loop is sometimes causing issues, so adding e.g. delay(1000); might make a difference.
The following example works quite nicely even with mp3 decoding: https://github.com/pschatzmann/arduino-audio-tools/blob/main/examples/examples-basic-api/base-player-a2dp/base-player-a2dp.ino

[RobotSquad]

i added in a delay of 1000 but still gives the same errors of
E (47066) task_wdt: Task watchdog got triggered. The following tasks did not reset the watchdog in time:
E (47066) task_wdt: - IDLE0 (CPU 0)
E (47066) task_wdt: Tasks currently running:
E (47066) task_wdt: CPU 0: BtA2dSourceT
E (47066) task_wdt: CPU 1: IDLE1
E (47066) task_wdt: Aborting.
abort() was called at PC 0x4015e888 on core 0

[RobotSquad]

i actually cannot use the Sdfat library so thats the reason i was using the other Bluetooth A2DP source example code

[pschatzmann]

I actually never tried with the SD or SDMMC library. What Arduino ESP32 version are you using ?
The latest is 2.0.5
Did you try the player example (with AudioSourceSD instead of AudioSourceSDFAT)?
Finally I recommend to remove all logger entries from the callback because they will break it from working

[pschatzmann]

I used your example, adapted it to work with the AudioKit and used a Wav file instead: It works like charm!

#include "BluetoothA2DPSource.h"
#include <SPI.h>
#include <SD.h>

#define PIN_AUDIO_KIT_SD_CARD_CS 13
#define PIN_AUDIO_KIT_SD_CARD_MISO 2
#define PIN_AUDIO_KIT_SD_CARD_MOSI 15
#define PIN_AUDIO_KIT_SD_CARD_CLK  14


static const char* TAG = "A2DP_DF";
BluetoothA2DPSource a2dp_source;
File sound_file;
const char* file_name = "/128.wav";
const int frame_size_bytes = sizeof(int16_t) * 2;

// callback used by A2DP to provide the sound data
int32_t get_sound_data(Frame *frame, int32_t len) {
  // the data in the file must be in int16 with 2 channels
  size_t result_len_bytes = sound_file.read((uint8_t*)frame, len * frame_size_bytes );
  // result is in number of frames
  int32_t result_len = result_len_bytes / frame_size_bytes;
  //ESP_LOGD("get_sound_data", "%d -> %d", len, result_len);
  return result_len;
}

// Arduino Setup
void setup(void) {
  Serial.begin(115200);
  //SPI.begin(14, 2, 15, 13);
  SPI.begin(PIN_AUDIO_KIT_SD_CARD_CLK, PIN_AUDIO_KIT_SD_CARD_MISO, PIN_AUDIO_KIT_SD_CARD_MOSI, PIN_AUDIO_KIT_SD_CARD_CS);

  // Setup SD and open file
  if (SD.begin(PIN_AUDIO_KIT_SD_CARD_CS)) {
    Serial.println("SD OPEN");
    sound_file = SD.open(file_name, FILE_READ);
    // go to audio
    sound_file.seek(44); 
    // start the bluetooth
    Serial.println("starting A2DP...");
    a2dp_source.start("LEXON MINO L", get_sound_data);
  }
}

// Arduino loop - repeated processing
void loop() {
}

[RobotSquad]

the IDE version? as for the IDE i am on 1.8.19

[pschatzmann]

So, go to Tools -> Board Manager and Enter ESP32. There you can see the Arduino ESP32 version which should be 2.0.5

[RobotSquad]

i am on 1.0.6 according to boards manager

[pschatzmann]

Very bad indeed! If you don't see the actual version numbers you will need to change the url in the Preferences
https://espressif-docs.readthedocs-hosted.com/projects/arduino-esp32/en/latest/installing.html

[RobotSquad]

after updating should i re-upload the code?

[RobotSquad]

Updating the esp32 version actually solved the issue! thanks a lot man!!