-
Notifications
You must be signed in to change notification settings - Fork 2
/
odt.xslt
548 lines (520 loc) · 20.3 KB
/
odt.xslt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" xmlns:meta="urn:oasis:names:tc:opendocument:xmlns:meta:1.0" xmlns:config="urn:oasis:names:tc:opendocument:xmlns:config:1.0" xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" xmlns:draw="urn:oasis:names:tc:opendocument:xmlns:drawing:1.0" xmlns:presentation="urn:oasis:names:tc:opendocument:xmlns:presentation:1.0" xmlns:dr3d="urn:oasis:names:tc:opendocument:xmlns:dr3d:1.0" xmlns:chart="urn:oasis:names:tc:opendocument:xmlns:chart:1.0" xmlns:form="urn:oasis:names:tc:opendocument:xmlns:form:1.0" xmlns:script="urn:oasis:names:tc:opendocument:xmlns:script:1.0" xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" xmlns:number="urn:oasis:names:tc:opendocument:xmlns:datastyle:1.0" xmlns:anim="urn:oasis:names:tc:opendocument:xmlns:animation:1.0" xmlns:dc="http://purl.org/dc/elements/1.1/" xmlns:xlink="http://www.w3.org/1999/xlink" xmlns:math="http://www.w3.org/1998/Math/MathML" xmlns:xforms="http://www.w3.org/2002/xforms" xmlns:fo="urn:oasis:names:tc:opendocument:xmlns:xsl-fo-compatible:1.0" xmlns:svg="urn:oasis:names:tc:opendocument:xmlns:svg-compatible:1.0" xmlns:smil="urn:oasis:names:tc:opendocument:xmlns:smil-compatible:1.0" xmlns:ooo="http://openoffice.org/2004/office" xmlns:ooow="http://openoffice.org/2004/writer" xmlns:oooc="http://openoffice.org/2004/calc" xmlns:int="http://opendocumentfellowship.org/internal" xmlns="http://www.w3.org/1999/xhtml" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" exclude-result-prefixes="office meta config text table draw presentation dr3d chart form script style number anim dc xlink math xforms fo svg smil ooo ooow oooc int #default">
<xsl:variable name="lineBreak">
<xsl:text>
</xsl:text>
</xsl:variable>
<xsl:template match="/office:document">
<html>
<head>
<xsl:apply-templates select="office:document-meta"/>
<script src="file:///home/user/odfmobile/data/jquery-1.2.3.js">/**/</script>
<script src="file:///home/user/odfmobile/data/document.js">/**/</script>
<xsl:call-template name="process-all-styles"/>
</head>
<xsl:apply-templates select="office:document-content"/>
</html>
</xsl:template>
<xsl:template match="office:document-content">
<body>
<xsl:apply-templates select="office:body/office:text"/>
<xsl:call-template name="add-footnote-bodies"/>
</body>
</xsl:template>
<xsl:template match="text:p">
<p class="{translate(@text:style-name,'.','_')}">
<xsl:apply-templates/>
<xsl:if test="count(node())=0"><br/></xsl:if>
</p>
</xsl:template>
<xsl:template match="text:span">
<span class="{translate(@text:style-name,'.','_')}">
<xsl:apply-templates/>
</span>
</xsl:template>
<xsl:template match="text:h">
<!-- Heading levels go only to 6 in XHTML -->
<xsl:variable name="level">
<xsl:choose>
<!-- text:outline-level is optional, default is 1 -->
<xsl:when test="not(@text:outline-level)">1</xsl:when>
<xsl:when test="@text:outline-level > 6">6</xsl:when>
<xsl:otherwise>
<xsl:value-of select="@text:outline-level"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:element name="{concat('h', $level)}">
<xsl:attribute name="class">
<xsl:value-of select="translate(@text:style-name,'.','_')"/>
</xsl:attribute>
<a name="{generate-id()}"/>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="text:tab">
<xsl:text xml:space="preserve"> </xsl:text>
</xsl:template>
<xsl:template match="text:line-break">
<br/>
</xsl:template>
<xsl:variable name="spaces" xml:space="preserve"/>
<xsl:template match="text:s">
<xsl:choose>
<xsl:when test="@text:c">
<xsl:call-template name="insert-spaces">
<xsl:with-param name="n" select="@text:c"/>
</xsl:call-template>
</xsl:when>
<xsl:otherwise>
<xsl:text> </xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template name="insert-spaces">
<xsl:param name="n"/>
<xsl:choose>
<xsl:when test="$n <= 30">
<xsl:value-of select="substring($spaces, 1, $n)"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="$spaces"/>
<xsl:call-template name="insert-spaces">
<xsl:with-param name="n">
<xsl:value-of select="$n - 30"/>
</xsl:with-param>
</xsl:call-template>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="text:a">
<a href="{@xlink:href}"><xsl:apply-templates/></a>
</xsl:template>
<xsl:template match="text:bookmark-start|text:bookmark">
<a name="{@text:name}">
<span style="font-size: 0px"><xsl:text> </xsl:text></span>
</a>
</xsl:template>
<xsl:template match="text:note">
<xsl:variable name="footnote-id" select="text:note-citation"/>
<a href="#footnote-{$footnote-id}">
<sup><xsl:value-of select="$footnote-id"/></sup>
</a>
</xsl:template>
<xsl:template match="text:note-body"/>
<xsl:template name="add-footnote-bodies">
<xsl:apply-templates select="//text:note" mode="add-footnote-bodies"/>
</xsl:template>
<xsl:template match="text:note" mode="add-footnote-bodies">
<xsl:variable name="footnote-id" select="text:note-citation"/>
<p><a name="footnote-{$footnote-id}"><sup><xsl:value-of select="$footnote-id"/></sup>:</a></p>
<xsl:apply-templates select="text:note-body/*"/>
</xsl:template>
<xsl:template name="process-all-styles">
<style type="text/css">
/* ODF paragraphs, by default, don't have any line spacing. */
p { margin: 0px; padding: 0px; }
/* put a default link style in, so we can see links */
a[href] { color: blue; text-decoration: underline; }
<xsl:apply-templates select="office:document-styles/office:styles"/>
<xsl:apply-templates select="office:document-content/office:automatic-styles"/>
<xsl:call-template name="toc-styles"/>
</style>
</xsl:template>
<xsl:template name="toc-styles">
<xsl:apply-templates select="//text:table-of-content" mode="toc-styles"/>
</xsl:template>
<xsl:template match="text:table-of-content" mode="toc-styles">
<!-- Generate styles for the ToC -->
/* ToC styles start */
<xsl:apply-templates select="//text:h/@text:outline-level" mode="toc-styles"/>
/* ToC styles end */
</xsl:template>
<xsl:template match="text:h/@text:outline-level" mode="toc-styles">
<xsl:text>.toc_outline_level_</xsl:text>
<xsl:value-of select="."/>
<xsl:text> { margin-left: </xsl:text>
<xsl:value-of select=".*0.5"/>
<xsl:text>cm; }</xsl:text>
<xsl:value-of select="$lineBreak"/>
<xsl:text>.toc_outline_level_</xsl:text>
<xsl:value-of select="."/>
<xsl:text> a { text-decoration: none } </xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="*" mode="toc-styles"/>
<xsl:template match="office:document-styles/office:styles">
/* Document styles start */
<xsl:apply-templates/>
/* Document styles end */
</xsl:template>
<xsl:template match="office:document-content/office:automatic-styles">
/* Automatic styles start */
<xsl:apply-templates/>
/* Automatic styles end */
</xsl:template>
<xsl:template match="style:default-style">
<xsl:choose>
<xsl:when test="@style:family='table'">
<xsl:text>table</xsl:text>
</xsl:when>
<xsl:when test="@style:family='table-cell'">
<xsl:text>td</xsl:text>
</xsl:when>
<xsl:when test="@style:family='table-row'">
<xsl:text>tr</xsl:text>
</xsl:when>
<xsl:when test="@style:family='paragraph'">
<xsl:text>p</xsl:text>
</xsl:when>
<xsl:when test="@style:family='text'">
<xsl:text>p</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>.default_</xsl:text>
<xsl:value-of select="translate(@style:family,'.','_')"/>
</xsl:otherwise>
</xsl:choose>
<xsl:text>{</xsl:text><xsl:value-of select="$lineBreak"/>
<xsl:call-template name="process-styles">
<xsl:with-param name="node" select="."/>
</xsl:call-template>
<xsl:text>}</xsl:text>
</xsl:template>
<xsl:template match="style:style">
<xsl:text>.</xsl:text>
<xsl:value-of select="translate(@style:name,'.','_')"/>
<xsl:text>{</xsl:text><xsl:value-of select="$lineBreak"/>
<xsl:call-template name="process-styles">
<xsl:with-param name="node" select="."/>
</xsl:call-template>
<xsl:text>}</xsl:text>
</xsl:template>
<xsl:template name="process-styles">
<xsl:param name="node"/>
<xsl:if test="$node/@style:parent-style-name">
<xsl:variable name="parentStyle" select="$node/@style:parent-style-name"/>
<xsl:call-template name="process-styles">
<xsl:with-param name="node" select="//style:style[@style:name=$parentStyle]"/>
</xsl:call-template>
</xsl:if>
<xsl:apply-templates select="$node/style:paragraph-properties/@*" mode="styleattr"/>
<xsl:apply-templates select="$node/style:text-properties/@*" mode="styleattr"/>
<xsl:apply-templates select="$node/style:table-cell-properties/@*" mode="styleattr"/>
<xsl:apply-templates select="$node/style:table-properties/@*" mode="styleattr"/>
<xsl:apply-templates select="$node/style:table-column-properties/@*" mode="styleattr"/>
<xsl:apply-templates select="$node/style:graphic-properties/@*" mode="styleattr"/>
</xsl:template>
<xsl:template match="@fo:border-left|@fo:border-right|@fo:border-top|@fo:border-bottom|@fo:border|@fo:margin-left|@fo:margin-right|@fo:margin-top|@fo:margin-bottom|@fo:margin|@fo:padding-left|@fo:padding-right|@fo:padding-top|@fo:padding-bottom|@fo:padding|@fo:text-align|@fo:text-indent|@fo:font-variant|@fo:font-family|@fo:color|@fo:background-color|@fo:font-size|@svg:font-family|@fo:font-style|@fo:font-weight|@fo:line-height|@style:width" mode="styleattr">
<xsl:call-template name="pass-through" />
</xsl:template>
<xsl:template match="@style:font-name" mode="styleattr">
<xsl:text>font-family: '</xsl:text>
<xsl:value-of select="."/><xsl:text>';</xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="@style:text-underline-style|@style:text-underline-type" mode="styleattr">
<!-- CSS2 only has one type of underline.
We can improve this when CSS3 is better supported.
-->
<xsl:if test="not(.='none')">
<xsl:text>text-decoration: underline;</xsl:text>
</xsl:if>
</xsl:template>
<xsl:template match="@fo:text-align" mode="styleattr">
<xsl:value-of select="local-name()"/><xsl:text>: </xsl:text>
<xsl:choose>
<xsl:when test=".='start'"><xsl:text>left</xsl:text></xsl:when>
<xsl:when test=".='end'"><xsl:text>right</xsl:text></xsl:when>
<xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
</xsl:choose>
<xsl:text>;</xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="@style:horizontal-pos" mode="styleattr">
<xsl:choose>
<!-- We can't support the others until we figure out pagination. -->
<xsl:when test=".='left'">
/* Left alignment */
<xsl:text>margin-left: 0; margin-right: auto;</xsl:text>
</xsl:when>
<xsl:when test=".='right'">
/* Right alignment */
<xsl:text>margin-left: auto; margin-right: 0;</xsl:text>
</xsl:when>
<xsl:when test=".='center'">
/* Centered alignment */
<xsl:text>margin-left: auto; margin-right: auto;</xsl:text>
</xsl:when>
</xsl:choose>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="@style:column-width" mode="styleattr">
<xsl:text>width: </xsl:text><xsl:value-of select="."/><xsl:text>;</xsl:text>
</xsl:template>
<xsl:template match="@*" mode="styleattr">
<!-- don't output anything for attrs we don't understand -->
</xsl:template>
<xsl:template name="pass-through">
<xsl:value-of select="local-name()"/><xsl:text>: </xsl:text>
<xsl:value-of select="."/><xsl:text>;</xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="text:list-level-style-bullet">
<xsl:text>.</xsl:text>
<xsl:value-of select="../@style:name"/>
<xsl:text>_</xsl:text>
<xsl:value-of select="@text:level"/>
<xsl:text>{ list-style-type: </xsl:text>
<xsl:choose>
<xsl:when test="@text:level mod 3 = 1">disc</xsl:when>
<xsl:when test="@text:level mod 3 = 2">circle</xsl:when>
<xsl:when test="@text:level mod 3 = 0">square</xsl:when>
<xsl:otherwise>decimal</xsl:otherwise>
</xsl:choose>
<xsl:text>;}</xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="text:list-level-style-number">
<xsl:text>.</xsl:text>
<xsl:value-of select="../@style:name"/>
<xsl:text>_</xsl:text>
<xsl:value-of select="@text:level"/>
<xsl:text>{ list-style-type: </xsl:text>
<xsl:choose>
<xsl:when test="@style:num-format='1'">decimal</xsl:when>
<xsl:when test="@style:num-format='I'">upper-roman</xsl:when>
<xsl:when test="@style:num-format='i'">lower-roman</xsl:when>
<xsl:when test="@style:num-format='A'">upper-alpha</xsl:when>
<xsl:when test="@style:num-format='a'">lower-alpha</xsl:when>
<xsl:otherwise>decimal</xsl:otherwise>
</xsl:choose>
<xsl:text>;}</xsl:text>
<xsl:value-of select="$lineBreak"/>
</xsl:template>
<xsl:template match="table:table">
<table class="{@table:style-name}">
<colgroup>
<xsl:apply-templates select="table:table-column"/>
</colgroup>
<xsl:if test="table:table-header-rows/table:table-row">
<thead>
<xsl:apply-templates select="table:table-header-rows/table:table-row"/>
</thead>
</xsl:if>
<tbody>
<xsl:apply-templates select="table:table-row"/>
</tbody>
</table>
</xsl:template>
<xsl:template match="table:table-column">
<col>
<xsl:if test="@table:number-columns-repeated">
<xsl:attribute name="span">
<xsl:value-of select="@table:number-columns-repeated"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@table:style-name">
<xsl:attribute name="class">
<xsl:value-of select="translate(@table:style-name,'.','_')"/>
</xsl:attribute>
</xsl:if>
</col>
</xsl:template>
<xsl:template match="table:table-row">
<tr>
<xsl:apply-templates select="table:table-cell"/>
</tr>
</xsl:template>
<xsl:template match="table:table-cell">
<xsl:variable name="n">
<xsl:choose>
<xsl:when test="@table:number-columns-repeated != 0">
<xsl:value-of select="@table:number-columns-repeated"/>
</xsl:when>
<xsl:otherwise>1</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:call-template name="process-table-cell">
<xsl:with-param name="n" select="$n"/>
</xsl:call-template>
</xsl:template>
<xsl:template name="process-table-cell">
<xsl:param name="n"/>
<xsl:if test="$n != 0">
<td>
<xsl:if test="@table:style-name">
<xsl:attribute name="class">
<xsl:value-of select="translate(@table:style-name, '.','_')"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@table:number-columns-spanned">
<xsl:attribute name="colspan">
<xsl:value-of select="@table:number-columns-spanned"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@table:number-rows-spanned">
<xsl:attribute name="rowspan">
<xsl:value-of select="@table:number-rows-spanned"/>
</xsl:attribute>
</xsl:if>
<xsl:apply-templates/>
</td>
<xsl:call-template name="process-table-cell">
<xsl:with-param name="n" select="$n - 1"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
<xsl:key name="listTypes" match="text:list-style" use="@style:name"/>
<xsl:template match="text:list">
<xsl:variable name="level" select="count(ancestor::text:list)+1"/>
<!-- the list class is the @text:style-name of the outermost
<text:list> element -->
<xsl:variable name="listClass">
<xsl:choose>
<xsl:when test="$level=1">
<xsl:value-of select="@text:style-name"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="ancestor::text:list[last()]/@text:style-name"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<!-- Now select the <text:list-level-style-foo> element at this
level of nesting for this list -->
<xsl:variable name="node" select="key('listTypes',$listClass)/*[@text:level='$level']"/>
<!-- emit appropriate list type -->
<xsl:choose>
<xsl:when test="local-name($node)='list-level-style-number'">
<ol class="{concat($listClass,'_',$level)}">
<xsl:apply-templates/>
</ol>
</xsl:when>
<xsl:otherwise>
<ul class="{concat($listClass,'_',$level)}">
<xsl:apply-templates/>
</ul>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="text:list-item">
<li><xsl:apply-templates/></li>
</xsl:template>
<xsl:template match="office:document-meta">
<xsl:apply-templates/>
</xsl:template>
<xsl:template match="office:meta">
<xsl:comment> Metadata starts </xsl:comment>
<xsl:apply-templates select="dc:title"/>
<xsl:apply-templates select="dc:creator"/>
<xsl:apply-templates select="dc:date"/>
<xsl:apply-templates select="dc:language"/>
<xsl:apply-templates select="dc:description"/>
<xsl:apply-templates select="meta:keyword"/>
<xsl:apply-templates select="meta:generator"/>
<meta http-equiv="Content-Type" content="text/html;charset=utf-8"/>
<xsl:comment> Metadata ends </xsl:comment>
</xsl:template>
<xsl:template match="dc:title">
<title><xsl:apply-templates/></title>
</xsl:template>
<xsl:template match="dc:language">
<meta http-equiv="content-language" content="{current()}"/>
</xsl:template>
<xsl:template match="dc:creator">
<meta name="author" content="{current()}"/>
<meta name="DC.creator" content="{current()}"/>
</xsl:template>
<xsl:template match="dc:description">
<meta name="description" content="{current()}"/>
</xsl:template>
<xsl:template match="dc:date">
<meta name="revised" content="{current()}"/>
<meta name="DC.date" content="{current()}"/>
</xsl:template>
<xsl:template match="meta:keyword">
<meta name="keywords" content="{current()}"/>
</xsl:template>
<xsl:template match="meta:generator">
<meta name="generator" content="{current()}"/>
</xsl:template>
<xsl:param name="param_track_changes"/>
<xsl:template match="text:tracked-changes">
<xsl:comment> Document has track-changes on </xsl:comment>
</xsl:template>
<xsl:template match="text:change">
<xsl:if test="$param_track_changes">
<xsl:variable name="id" select="@text:change-id"/>
<xsl:variable name="change" select="//text:changed-region[@text:id=$id]"/>
<xsl:element name="del">
<xsl:attribute name="datetime">
<xsl:value-of select="$change//dc:date"/>
</xsl:attribute>
<xsl:apply-templates/>
</xsl:element>
</xsl:if>
</xsl:template>
<xsl:template match="office:change-info"/>
<xsl:param name="param_baseuri"/>
<xsl:template match="draw:frame">
<xsl:element name="div">
<xsl:attribute name="class">
<xsl:value-of select="translate(@draw:style-name,'.','_')"/>
</xsl:attribute>
<xsl:attribute name="style">
<!-- This border could be removed, but OOo does default
to showing a border. -->
border: 1px solid #888;
<xsl:if test="@svg:width">
width: <xsl:value-of select="@svg:width"/>;
</xsl:if>
<xsl:if test="@svg:height">
height: <xsl:value-of select="@svg:height"/>;
</xsl:if>
</xsl:attribute>
<xsl:apply-templates/>
</xsl:element>
</xsl:template>
<xsl:template match="draw:frame/draw:image">
<xsl:element name="img">
<xsl:attribute name="style">
<!-- Default behaviour -->
width: 100%;
height: 100%;
<xsl:if test="not(../@text:anchor-type='character')">
display: block;
</xsl:if>
</xsl:attribute>
<xsl:attribute name="alt">
<xsl:value-of select="../svg:desc"/>
</xsl:attribute>
<xsl:attribute name="src">
<xsl:value-of select="concat($param_baseuri,@xlink:href)"/>
</xsl:attribute>
</xsl:element>
</xsl:template>
<xsl:template match="svg:desc"/>
<xsl:template match="text:table-of-content">
<!-- We don't parse the app's ToC but generate our own. -->
<div class="toc">
<xsl:apply-templates select="text:index-body/text:index-title"/>
<xsl:apply-templates select="//text:h" mode="toc"/>
</div>
</xsl:template>
<xsl:template match="text:h" mode="toc">
<xsl:element name="p">
<xsl:attribute name="class">
<xsl:text>toc_outline_level_</xsl:text>
<xsl:choose>
<xsl:when test="@text:outline-level">
<xsl:value-of select="@text:outline-level"/>
</xsl:when>
<!-- ODF spec says that when unspecified the outline
level should be considered to be 1. -->
<xsl:otherwise>1</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<a href="#{generate-id()}"><xsl:value-of select="."/></a>
</xsl:element>
</xsl:template>
</xsl:stylesheet>