build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    def getVersionCode = {
        def stdout = new ByteArrayOutputStream()
        exec {
            commandLine 'git', 'rev-list', '--count', 'HEAD'
            standardOutput = stdout
        }
        return stdout.toString().trim().toInteger()
    }

    def getVersionName = {
        return new Date().format('yy.MM.dd')
    }

    ext.version_name = getVersionName()
    ext.version_code = getVersionCode()
    repositories {
        google()
        jcenter()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.2'
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:3.5.0.2730"
        classpath "com.hiya:jacoco-android:0.2"
    }
}

allprojects {
    repositories {
        google()
        jcenter()
    }

}

task clean(type: Delete) {
    delete rootProject.buildDir
}

apply plugin: "org.sonarqube"

//sonar configuration
sonarqube {
    properties {
        property "sonar.organization", "mercuriete-github"
        property "sonar.projectKey", "mercuriete_android-mrz-reader"
        property "sonar.host.url", "https://sonarcloud.io"

        property "sonar.projectVersion", project.version_name
        property "sonar.sourceEncoding", "UTF-8"

        property "sonar.coverage.jacoco.xmlReportPaths", getRootDir().toString() + "/MRZReader/build/jacoco/jacoco.xml"
        property "sonar.junit.reportsPath", getRootDir().toString() + "/MRZReader/build/test-results/testDebugUnitTest/"
        property "sonar.androidLint.reportPaths", getRootDir().toString() + "/MRZReader/build/reports/lint-results-debug.xml"
    }
}