build.gradle

// Defines common configuration for each of the 3 subprojects.
subprojects {
	apply plugin: "java-library"
	apply plugin: "maven-publish"

	group = "com.marklogic"
	version = "5.0.0"

	java {
		sourceCompatibility = JavaVersion.VERSION_1_8
		targetCompatibility = JavaVersion.VERSION_1_8
	}

	repositories {
		mavenLocal()
		mavenCentral()
		maven {
			url "https://bed-artifactory.bedford.progress.com:443/artifactory/ml-maven-snapshots/"
		}
	}

	dependencies {
		// Forcing Spring to use logback instead of commons-logging
		testImplementation "ch.qos.logback:logback-classic:1.3.14" // Not using 1.4.x yet as it requires Java 11
		testImplementation 'org.slf4j:jcl-over-slf4j:2.0.13'
		testImplementation 'org.slf4j:slf4j-api:2.0.13'
	}

	task javadocJar(type: Jar, dependsOn: javadoc) {
		archiveClassifier = "javadoc"
		from javadoc
	}
	javadoc.failOnError = false
	// Ignores warnings on params that don't have descriptions, which is a little too noisy
	javadoc.options.addStringOption('Xdoclint:none', '-quiet')

	test {
		useJUnitPlatform()
		testLogging {
			events 'started','passed', 'skipped', 'failed'
			exceptionFormat 'full'
		}
	}

	// Publishing setup - see https://docs.gradle.org/current/userguide/publishing_setup.html .
	java {
		withJavadocJar()
		withSourcesJar()
	}

	publishing {
		publications {
			mainJava(MavenPublication) {
				groupId = group
				artifactId = project.name
				version = version
				from components.java
				pom {
					name = "${group}:${project.name}"
					description = "${projectDescription}"
					packaging = "jar"
					url = "https://github.com/marklogic/${project.name}"
					licenses {
						license {
							name = "The Apache License, Version 2.0"
							url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
						}
					}
					developers {
						developer {
							id = "marklogic"
							name = "MarkLogic Github Contributors"
							email = "general@developer.marklogic.com"
							organization = "MarkLogic"
							organizationUrl = "https://www.marklogic.com"
						}
					}
					scm {
						url = "git@github.com:marklogic/ml-gradle.git"
						connection = "scm:git@github.com:marklogic/ml-gradle.git"
						developerConnection = "scm:git@github.com:marklogic/ml-gradle.git"
					}
				}
			}
		}
		repositories {
			maven {
				if (project.hasProperty("mavenUser")) {
					credentials {
						username mavenUser
						password mavenPassword
					}
					url publishUrl
					allowInsecureProtocol = true
				} else {
					name = "central"
					url = mavenCentralUrl
					credentials {
						username mavenCentralUsername
						password mavenCentralPassword
					}
				}
			}
		}
	}
}