-
Notifications
You must be signed in to change notification settings - Fork 1
/
common_pre.pri
102 lines (83 loc) · 2.59 KB
/
common_pre.pri
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
CONFIG += c++11
# Disable GNU extensions (default for Qt 5.5 and older)
# See ff4444065158285b573c6fc0a91c9e75fc7ddd96
# https://codereview.qt-project.org/#/c/121023/
CONFIG += strict_c++
CONFIG(release, debug|release): DEFINES += NDEBUG
defineTest(osx) {
macx: return(true)
return(false)
}
defineTest(osxDebug) {
osx():CONFIG(debug, debug|release): return(true)
return(false)
}
defineTest(osxRelease) {
osx():CONFIG(release, debug|release): return(true)
return(false)
}
defineTest(windows) {
win32: return(true)
return(false)
}
defineTest(windowsDebug) {
windows():CONFIG(debug, debug|release): return(true)
return(false)
}
defineTest(windowsRelease) {
windows():CONFIG(release, debug|release): return(true)
return(false)
}
defineTest(linux) {
unix:!mac: return(true)
return(false)
}
defineTest(linuxDebug) {
linux():CONFIG(debug, debug|release): return(true)
return(false)
}
defineTest(linuxRelease) {
linux():CONFIG(release, debug|release): return(true)
return(false)
}
# For $$QT_ARCH see https://bugreports.qt.io/browse/QTBUG-30263
contains(QT_ARCH, x86_64) {
ARCH = x86_64
} else {
ARCH = x86_32
}
windowsRelease(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT\..\build-windows-$$ARCH-release
else:windowsDebug(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT\..\build-windows-$$ARCH-debug
else:osxRelease(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT/../build-osx-$$ARCH-release
else:osxDebug(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT/../build-osx-$$ARCH-debug
else:linuxRelease(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT/../build-linux-$$ARCH-release
else:linuxDebug(): CMAKE_DEPENDENCIES_ROOT = $$BUILD_ROOT/../build-linux-$$ARCH-debug
else: error("Unknown os")
LIBKULLO_BIN_DIR = $$CMAKE_DEPENDENCIES_ROOT/bin-libkullo
# Add farcaster repo root and libkullo include dir to include path
INCLUDEPATH += $$PWD
INCLUDEPATH += $$LIBKULLO_BIN_DIR/include
DEFINES += BOOST_ALL_NO_LIB
macx {
QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.12
}
# Hardening
linuxRelease(): {
QMAKE_CXXFLAGS += -fstack-protector -fPIE -D_FORTIFY_SOURCE=2
QMAKE_LFLAGS += -pie -z relro -z now
}
# Breakpad
*-g++:CONFIG(release, debug|release) {
QMAKE_CXXFLAGS += -g
}
# Fix make's $(DEL_DIR)
#
# rmdir:
# /s : Removes the specified directory and all subdirectories including any files. Use /s to remove a tree.
# /q : Runs rmdir in quiet mode. Deletes directories without confirmation.
#
# rm:
# -f ignore nonexistent files and arguments, never prompt
# -r remove directories and their contents recursively
win32:QMAKE_DEL_DIR = rmdir /s /q
unix:QMAKE_DEL_DIR = rm -rf