Home

Converting Text to XML, JSON, or YAML

Gelatin is a combined lexer, parser, and output generator. It is a simple language for converting text into a structured formats.

Example

Suppose you want to convert the following text file to XML:

User
----
Name: John, Lastname: Doe
Office: 1st Ave
Birth date: 1978-01-01

User
----
Name: Jane, Lastname: Foo
Office: 2nd Ave
Birth date: 1970-01-01

The following Gelatin syntax does the job:

# Define commonly used data types. This is optional, but
# makes your life a litte easier by allowing to reuse regular
# expressions in the grammar.
define nl /[\r\n]/
define ws /\s+/
define fieldname /\w+/
define value /[^\r\n,]/
define field_end /[\r\n,]/

grammar user:
    match nl:
        do.return()
    match ws:
        do.next()
    match fieldname ':' ws value field_end:
        out.add('$0', '$3')

# The grammar named "input" is the entry point for the converter.
grammar input:
    match 'User' nl '----':
        out.enter('user')
        user()

Explanation:

1. “grammar input:” is the entry point for the converter.
2. The match statements in each grammar are executed sequentially. If a match is found, the statements under the match are executed, and the grammar is re-executed sequentially.
3. If the end of a grammar is reached before the end of the input document was reached, an error is raised.
4. out.add(‘$0’, ‘$3’) creates a node in the XML (or JSON, or YAML). The name of the node is the value of the first matched field (the fieldname, in this case). The data of the node is the value of the fourth matched field.
5. out.enter(‘user’) creates a “user” node in the output and selects it such that all following “add” statements generate output relative to the “user” node. Gelatin automatically leaves the user node upon leaving the match statement.
6. user() calls the grammar named “user”.

Starting the transformation

The following command converts the input to XML:

./gel -s mysyntax.gel input.txt

The some for JSON or YAML:

./gel -s mysyntax.gel -f json input.txt
./gel -s mysyntax.gel -f yaml input.txt

Advanced Usage

Generating XML attributes

grammar input:
    match 'User' nl '----' nl 'Name:' ws value field_end:
        out.enter('user?name="$6"')
        user()

Skipping Values

match /# .*[\r\n]/:
        do.skip()

Matching Multiple Values

match /# .*[\r\n]/
    | '/*' /[^\r\n]/ '*/' nl:
    do.skip()