NXQ_00270.rq

#+ summary: Lists proteins belonging to Rett syndrome pathways, and their subcellular locations (GOLD)
#+ endpoint_in_url: False
#+ tags:
#+   - Federation with WikiPathways

PREFIX wp: <http://vocabularies.wikipathways.org/wp#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX : <http://nextprot.org/rdf#>

select distinct ?entry str(?gen) ?pathwayname (group_concat(distinct str(?loclab); SEPARATOR = ",") as ?locs)  where {
    service <http://85.214.42.229:8890/sparql> {

        {?geneProduct a wp:Protein}
            union
        {?geneProduct a wp:GeneProduct}
 
        ?geneProduct rdfs:label ?gen .
        filter(!regex(?gen,"[ a-z-]")). # ensures official gene names for subsequent neXtprot matching
        ?geneProduct dcterms:isPartOf ?pathway .
        ?pathway a wp:Pathway .
        ?pathway wp:organism ?organism .
        filter(contains(str(?organism),"9606"))
        ?pathway dc:title ?pathwayname .
        filter(regex(?pathwayname,"rett","i")).
    }
    ?entry a :Entry .
    ?entry :gene / :name ?gen .
    ?entry :isoform ?iso.
    ?iso :cellularComponent ?locannot .
    ?locannot :term ?locterm .
    ?locterm rdfs:label ?loclab .
    ?locannot :evidence ?locev .
    ?locev :quality :GOLD .
    filter not exists {?locannot :negativeEvidence ?locev .}
}
order by ?entry