common.gradle

// Gradle settings and tasks common to all Archer Game Template subprojects

apply plugin: 'application'
apply plugin: 'java'

sourceCompatibility = JavaVersion.VERSION_11
targetCompatibility = JavaVersion.VERSION_11
ext.jmeVersion = '3.6.1-stable'

tasks.withType(JavaExec) { // Java runtime options:
    enableAssertions true
}

repositories {
    //mavenLocal()
    mavenCentral()
}

dependencies {
    implementation 'com.github.stephengold:Heart:8.8.0'
    implementation 'com.github.stephengold:Minie:7.8.1+big3'
    implementation 'com.github.stephengold:SkyControl:1.0.5'
    implementation 'org.jmonkeyengine:jme3-core:' + jmeVersion
    implementation 'org.jmonkeyengine:jme3-desktop:' + jmeVersion
    implementation 'org.jmonkeyengine:jme3-effects:' + jmeVersion
    runtimeOnly    'org.jmonkeyengine:jme3-awt-dialogs:' + jmeVersion
    runtimeOnly    'org.jmonkeyengine:jme3-jogg:' + jmeVersion
    implementation 'org.jmonkeyengine:jme3-plugins:' + jmeVersion

    // select one version of LWJGL
    //runtimeOnly 'org.jmonkeyengine:jme3-lwjgl:' + jmeVersion  // LWJGL 2.x
    runtimeOnly 'org.jmonkeyengine:jme3-lwjgl3:' + jmeVersion // LWJGL 3.x

    implementation files('../lib/shaderblow-ex-1.0.0.jar')
    runtimeOnly    files('../lib/jme-materialize.jar')
}

// cleanup tasks:

clean.dependsOn('cleanDLLs', 'cleanSOs')

tasks.register('cleanDLLs', Delete) { // extracted Windows native libraries
    delete fileTree(dir: '.', include: '*.dll')
}
tasks.register('cleanSOs', Delete) { // extracted Linux native libraries
    delete fileTree(dir: '.', include: '*.so')
}