build.gradle

apply plugin: 'groovy'

repositories {
    jcenter()
    maven {
        url 'https://repo.jenkins-ci.org/public/'
    }
}

dependencies {
    // main dependencies
    compile group: 'org.codehaus.groovy', name: 'groovy-all', version: '2.4.6'
    compile group: 'com.cloudbees', name: 'groovy-cps', version: '1.24'
    compile group: 'org.jenkins-ci.main', name: 'jenkins-core', version: '2.102'

    // @grab dependencies
    compile group: 'org.apache.commons', name: 'commons-lang3', version: '3.8.1'
    compile group: 'org.yaml', name: 'snakeyaml', version: '1.23'

    // test dependencies
    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'com.lesfurets', name: 'jenkins-pipeline-unit', version: '1.1'
}

task cleanDist(type: Delete) {
    delete 'dist'
}

task copyDist(type: Copy) {
    from('./') {
        include 'resources/**/*'
        include 'test-vars/**/*'
    }
    into 'dist/jenkins-shared-library@master'
    doLast {
        file('dist/jenkins-shared-library@master/test-vars')
            .renameTo(file('dist/jenkins-shared-library@master/vars'))
    }
}

test {
    dependsOn cleanDist
    dependsOn copyDist
    systemProperty 'groovy.grape.enable', 'false'
    testLogging.showStandardStreams = true
    beforeTest { descriptor ->
        logger.lifecycle("Running test: " + descriptor)
    }
}

test.outputs.upToDateWhen {
    false
}

compileGroovy {
    groovyOptions.forkOptions.jvmArgs = ['-Dgroovy.grape.enable=false']
}

compileTestGroovy {
    groovyOptions.forkOptions.jvmArgs = ['-Dgroovy.grape.enable=false']
}

sourceSets {
    main {
        groovy {
            srcDirs = ['src']
        }
    }

    test {
        groovy {
            srcDirs = ['test']
        }
    }

    resources {
        groovy {
            srcDirs = ['resources', 'test-resources']
        }
    }
}