forked from Yubico/yubikey-personalization-gui
-
Notifications
You must be signed in to change notification settings - Fork 1
/
YKPersonalization.pro
393 lines (335 loc) · 13.4 KB
/
YKPersonalization.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
#
# global definitions
#
VERSION_MAJOR = 3
VERSION_MINOR = 1
VERSION_BUILD = 15
VERSION = "$${VERSION_MAJOR}.$${VERSION_MINOR}.$${VERSION_BUILD}"
APP_NAME = $$quote(YubiKey Personalization Tool)
#
# common configuration
#
QT += core gui
DEPLOYMENT_PLUGIN += qmng
TEMPLATE = app
TARGET = yubikey-personalization-gui
DEFINES += VERSION_MAJOR=\\\"$${VERSION_MAJOR}\\\" VERSION_MINOR=\\\"$${VERSION_MINOR}\\\" VERSION_BUILD=\\\"$${VERSION_BUILD}\\\" VERSION=\\\"$${VERSION}\\\"
CONFIG += exceptions
# if this is qt5, add widgets
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
!nosilent {
CONFIG += silent
}
CONFIG(debug, debug|release) {
message("Debug build")
TARGET_DIR = build$${DIR_SEPARATOR}debug
QT += testlib
CONFIG += console no_lflags_merge
} else {
message("Release build")
TARGET_DIR = build$${DIR_SEPARATOR}release
DEFINES += QT_NO_DEBUG_OUTPUT
}
UI_DIR = ./src/ui
RCC_DIR = "$$TARGET_DIR/RCCFiles"
MOC_DIR = "$$TARGET_DIR/MOCFiles"
OBJECTS_DIR = "$$TARGET_DIR/ObjFiles"
DESTDIR = "$$TARGET_DIR"
DEPENDPATH += . src src/ui
INCLUDEPATH += . src src/ui
LICENSEFILES = json-c.txt \
libyubikey.txt \
yubikey-personalization.txt
FORMS += \
src/ui/toolpage.ui \
src/ui/staticpage.ui \
src/ui/settingpage.ui \
src/ui/otppage.ui \
src/ui/oathpage.ui \
src/ui/mainwindow.ui \
src/ui/helpbox.ui \
src/ui/confirmbox.ui \
src/ui/chalresppage.ui \
src/ui/aboutpage.ui \
src/ui/diagnostics.ui \
src/ui/yubiaccbox.ui
HEADERS += \
src/ui/toolpage.h \
src/ui/staticpage.h \
src/ui/settingpage.h \
src/ui/scanedit.h \
src/ui/otppage.h \
src/ui/oathpage.h \
src/ui/mainwindow.h \
src/ui/helpbox.h \
src/ui/confirmbox.h \
src/ui/chalresppage.h \
src/ui/aboutpage.h \
src/ui/diagnostics.h \
src/ui/yubiaccbox.h \
src/yubikeywriter.h \
src/yubikeyutil.h \
src/yubikeylogger.h \
src/yubikeyfinder.h \
src/yubikeyconfig.h \
src/version.h \
src/otpdef.h \
src/help.h \
src/common.h
SOURCES += \
src/main.cpp \
src/ui/toolpage.cpp \
src/ui/staticpage.cpp \
src/ui/settingpage.cpp \
src/ui/scanedit.cpp \
src/ui/otppage.cpp \
src/ui/oathpage.cpp \
src/ui/mainwindow.cpp \
src/ui/helpbox.cpp \
src/ui/confirmbox.cpp \
src/ui/chalresppage.cpp \
src/ui/aboutpage.cpp \
src/ui/yubiaccbox.cpp \
src/ui/diagnostics.cpp \
src/yubikeywriter.cpp \
src/yubikeyutil.cpp \
src/yubikeylogger.cpp \
src/yubikeyfinder.cpp \
src/yubikeyconfig.cpp
RESOURCES += \
resources/resources.qrc
OTHER_FILES += \
resources/win/resources.rc \
resources/mac/Yubico.icns \
resources/mac/Info.plist.in \
resources/mac/qt.conf
cross {
message("Doing a cross platform build..")
QMAKE_CXXFLAGS += $$(CXXFLAGS)
QMAKE_LFLAGS += $$(LDFLAGS)
# pickup compiler from environment
_TARGET_ARCH = $$(TARGET_ARCH)
isEmpty(_TARGET_ARCH) {
error("Cross compiling without a target is completely invalid, set TARGET_ARCH")
}
QMAKE_CC = $$(TARGET_ARCH)-gcc
QMAKE_CXX = $$(TARGET_ARCH)-g++
QMAKE_LINK = $$QMAKE_CXX
QMAKE_LINK_C = $$QMAKE_CC
win32 {
QMAKE_LIB = $$(TARGET_ARCH)-ar -ru
QMAKE_RC = $$(TARGET_ARCH)-windres $$quote(-DVERSION_WIN_STR=\'\\\"$${VERSION}\\0\\\"\')
QMAKE_MOC = $$[QT_INSTALL_BINS]/moc
QMAKE_UIC = $$[QT_INSTALL_BINS]/uic
QMAKE_IDC = $$[QT_INSTALL_BINS]/idc
QMAKE_RCC = $$[QT_INSTALL_BINS]/rcc
QMAKE_LFLAGS += -static-libstdc++ -static-libgcc
}
_QTDIR = $$(QTDIR)
!isEmpty (_QTDIR) {
_QT_INCDIR = $$(QTDIR)$${DIR_SEPARATOR}include
_QT_LIBDIR = $$(QTDIR)$${DIR_SEPARATOR}lib
_QT_BINDIR = $$(QTDIR)$${DIR_SEPARATOR}bin
_QT_PLUGINDIR = $$(QTDIR)$${DIR_SEPARATOR}plugins
} else {
_QT_INCDIR = $$(QT_INCDIR)
_QT_LIBDIR = $$(QT_LIBDIR)
_QT_BINDIR = $$(QT_BINDIR)
_QT_PLUGINDIR = $$(QT_PLUGINDIR)
}
!isEmpty (_QT_INCDIR) {
QMAKE_INCDIR_QT = $$_QT_INCDIR
}
!isEmpty (_QT_LIBDIR) {
QMAKE_LIBDIR_QT = $$_QT_LIBDIR
}
}
#
# Windows specific configuration
#
win32 {
INCLUDEPATH += libs/win32/include libs/win32/include/ykpers-1
HEADERS += src/crandom.h
SOURCES += src/crandom.cpp
# The application icon
RC_FILE = resources/win/resources.rc
# The application dependencies
!contains(QMAKE_TARGET.arch, x86_64) {
message("Windows x86 build")
LIBS += $$quote(-L./libs/win32/bin) -llibyubikey-0 -llibykpers-1-1
} else {
message("Windows x86_64 build")
LIBS += $$quote(-L./libs/win64/bin) -llibyubikey-0 -llibykpers-1-1
}
CONFIG(debug, debug|release) {
LIB_FILES += \
$$_QT_BINDIR$${DIR_SEPARATOR}QtCored4.dll \
$$_QT_BINDIR$${DIR_SEPARATOR}QtGuid4.dll \
$$_QT_BINDIR$${DIR_SEPARATOR}QtTestd4.dll \
$$_QT_PLUGINDIR$${DIR_SEPARATOR}imageformats$${DIR_SEPARATOR}qmngd4.dll
} else {
LIB_FILES += \
$$_QT_BINDIR$${DIR_SEPARATOR}QtCore4.dll \
$$_QT_BINDIR$${DIR_SEPARATOR}QtGui4.dll \
$$_QT_PLUGINDIR$${DIR_SEPARATOR}imageformats$${DIR_SEPARATOR}qmng4.dll
}
LIB_FILES += \
$$_QT_BINDIR$${DIR_SEPARATOR}libgcc_s_dw2-1.dll \
$$_QT_BINDIR$${DIR_SEPARATOR}mingwm10.dll \
libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libjson-c-2.dll \
libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libyubikey-0.dll \
libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}bin$${DIR_SEPARATOR}libykpers-1-1.dll
isEmpty(TIMESTAMP_URL):TIMESTAMP_URL = 'http://timestamp.verisign.com/scripts/timstamp.dll'
LIB_FILES_WIN = $${LIB_FILES}
TARGET_DIR_WIN = $${DESTDIR}
for(FILE, LIB_FILES_WIN) {
QMAKE_POST_LINK +=$$quote($$QMAKE_COPY $${FILE} $${TARGET_DIR_WIN}$$escape_expand(\\n\\t))
}
LICENSE_DIR = $${TARGET_DIR_WIN}$${DIR_SEPARATOR}licenses
QMAKE_POST_LINK += $$quote($$QMAKE_MKDIR $${LICENSE_DIR}$$escape_expand(\\n\\t))
BASEDIR = libs$${DIR_SEPARATOR}win32$${DIR_SEPARATOR}licenses$${DIR_SEPARATOR}
for(FILE, LICENSEFILES) {
QMAKE_POST_LINK += $$quote($$QMAKE_COPY $${BASEDIR}$${FILE} $${LICENSE_DIR}$$escape_expand(\\n\\t))
}
QMAKE_POST_LINK += $$quote($$QMAKE_COPY COPYING $${LICENSE_DIR}$${DIR_SEPARATOR}yubikey-personalization-gui.txt$$escape_expand(\\n\\t))
sign_binaries {
_PVK_FILE = $$(PVK_FILE)
_SPC_FILE = $$(SPC_FILE)
isEmpty(_PVK_FILE) {
error("Must have a pvk file to sign (PVK_FILE env variable).")
}
isEmpty(_SPC_FILE) {
error("Must have a spc file to sign (SPC_FILE env variable).")
}
# sign all Yubico binaries
SIGN_FILES = $${TARGET}.exe \
libyubikey-0.dll \
libykpers-1-1.dll
for(FILE, SIGN_FILES) {
QMAKE_POST_LINK += $$quote("signcode -spc $$(SPC_FILE) -v $$(PVK_FILE) -a sha1 -$ commercial -n '$${APP_NAME}' -i 'http://www.yubico.com' -t $${TIMESTAMP_URL} $${TARGET_DIR_WIN}$${DIR_SEPARATOR}$${FILE}"$$escape_expand(\\n\\t))
}
}
build_installer {
QMAKE_POST_LINK += $$quote("makensis -DYKPERS_VERSION=$${VERSION} installer/win-nsis/ykpers.nsi"$$escape_expand(\\n\\t))
sign_binaries {
QMAKE_POST_LINK += $$quote("signcode -spc $$(SPC_FILE) -v $$(PVK_FILE) -a sha1 -$ commercial -n '$${APP_NAME} Installer' -i 'http://www.yubico.com' -t '$${TIMESTAMP_URL}' $${TARGET_DIR_WIN}$${DIR_SEPARATOR}$${TARGET}-$${VERSION}.exe"$$escape_expand(\\n\\t))
}
}
}
#
# *nix specific configuration
#
unix:!macx|force_pkgconfig {
message("Unix build")
LIBS += -lyubikey
CONFIG += link_pkgconfig
PKGCONFIG += ykpers-1
QMAKE_CXXFLAGS += $$(CXXFLAGS)
QMAKE_LFLAGS += $$(LDFLAGS)
}
#
# MacOS X specific configuration
#
macx:!force_pkgconfig {
message("Mac build")
INCLUDEPATH += libs/macx/include libs/macx/include/ykpers-1
LIBS += libs/macx/lib/libykpers-1.dylib libs/macx/lib/libyubikey.dylib
CONFIG += x86_64
DEFINES += QT_MAC_USE_COCOA
_QT_LIBDIR = $$QMAKE_LIBDIR_QT
_QT_PLUGINDIR = $$[QT_INSTALL_PLUGINS]
for_store {
QMAKE_CFLAGS += -gdwarf-2
QMAKE_CXXFLAGS += -gdwarf-2
isEmpty(PACKAGE_SIGN_IDENTITY):PACKAGE_SIGN_IDENTITY = '3rd Party Mac Developer Application'
isEmpty(INSTALLER_SIGN_IDENTITY):INSTALLER_SIGN_IDENTITY = '3rd Party Mac Developer Installer'
} else {
isEmpty(PACKAGE_SIGN_IDENTITY):PACKAGE_SIGN_IDENTITY = 'Developer ID Application'
isEmpty(INSTALLER_SIGN_IDENTITY):INSTALLER_SIGN_IDENTITY = 'Developer ID Installer'
}
# The application dependencies
LIBS += $$_SDK/System/Library/Frameworks/CoreFoundation.framework/Versions/A/CoreFoundation
LIBS += $$_SDK/System/Library/Frameworks/IOKit.framework/Versions/A/IOKit
# The application executable name
TARGET = $$APP_NAME
TARGET_MAC = $${TARGET}
TARGET_MAC ~= s, ,\\ ,g
# The application icon
ICON = resources/mac/Yubico.icns
# Copy required resources into the final app bundle and
# put the current version number into Info.plist
QMAKE_POST_LINK += $$quote(mkdir -p $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources && \
cp -R resources/mac/Yubico.icns $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources/. && \
cp resources/mac/qt.conf $${DESTDIR}/$${TARGET_MAC}.app/Contents/Resources/. && \
sed -e \'s|@@version@@|$$VERSION|g\' \
< resources/mac/Info.plist.in > $${DESTDIR}/$${TARGET_MAC}.app/Contents/Info.plist)
# copy the QT libraries into our bundle
_BASEDIR = $${DESTDIR}/$${TARGET_MAC}.app/Contents
_FRAMEWORKDIR = $${_BASEDIR}/Frameworks
_PLUGINDIR = $${_BASEDIR}/PlugIns
QMAKE_POST_LINK += $$quote( && mkdir -p $$_FRAMEWORKDIR && \
cp -R $$_QT_LIBDIR/QtCore.framework $$_FRAMEWORKDIR/QtCore.framework && \
rm -rf $$_FRAMEWORKDIR/QtCore.framework/Versions/4/Headers && \
cp -R $$_QT_LIBDIR/QtGui.framework $$_FRAMEWORKDIR/QtGui.framework && \
rm -rf $$_FRAMEWORKDIR/QtGui.framework/Versions/4/Headers && \
find $$_FRAMEWORKDIR -type l -print0 | xargs -0 rm -f && \
test -d $$_BASEDIR/Resources/qt_menu.nib || \
mv $$_FRAMEWORKDIR/QtGui.framework/Versions/4/Resources/qt_menu.nib $$_BASEDIR/Resources/qt_menu.nib && \
test ! -d $$_FRAMEWORKDIR/QtGui.framework/Versions/4/Resources || \
rmdir $$_FRAMEWORKDIR/QtGui.framework/Versions/4/Resources && \
mkdir -p $$_PLUGINDIR/imageformats && \
cp -R $$_QT_PLUGINDIR/imageformats/libqmng.dylib $$_PLUGINDIR/imageformats)
# copy libykpers and friends
_LIBDIR = $${_BASEDIR}/lib
QMAKE_POST_LINK += $$quote( && mkdir -p $$_LIBDIR && \
cp libs/macx/lib/libyubikey.0.dylib $$_LIBDIR && \
cp libs/macx/lib/libykpers-1.1.dylib $$_LIBDIR && \
cp libs/macx/lib/libjson-c.2.dylib $$_LIBDIR)
_LICENSEDIR = $${_BASEDIR}/licenses
QMAKE_POST_LINK += $$quote(&& mkdir -p $$_LICENSEDIR && \
cp COPYING $$_LICENSEDIR/yubikey-personalization-gui.txt)
for(FILE, LICENSEFILES) {
QMAKE_POST_LINK += $$quote(&& cp libs/macx/licenses/$${FILE} $$_LICENSEDIR)
}
# fixup all library paths..
_BASE = $$quote(@executable_path/../Frameworks)
_QTCORE = $$quote(QtCore.framework/Versions/4/QtCore)
_QTGUI = $$quote(QtGui.framework/Versions/4/QtGui)
isEmpty(_TARGET_ARCH) {
_INSTALL_NAME_TOOL = install_name_tool
} else {
_INSTALL_NAME_TOOL = $$(TARGET_ARCH)-install_name_tool
}
QMAKE_POST_LINK += $$quote( && $$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/$$_QTCORE $$_BASEDIR/MacOS/$$TARGET_MAC && \
$$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/$$_QTGUI $$_BASEDIR/MacOS/$$TARGET_MAC && \
$$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/$$_QTCORE $$_FRAMEWORKDIR/$$_QTGUI && \
$$_INSTALL_NAME_TOOL -change $$_QTCORE $$_BASE/$$_QTCORE $$_PLUGINDIR/imageformats/libqmng.dylib && \
$$_INSTALL_NAME_TOOL -change $$_QTGUI $$_BASE/$$_QTGUI $$_PLUGINDIR/imageformats/libqmng.dylib)
build_installer {
# the productbuild path doesn't work pre 10.8
for_store {
_INSTALLER_CMD = "productbuild --sign \'$$INSTALLER_SIGN_IDENTITY\' --component $${DESTDIR}/$${TARGET_MAC}.app /Applications/ $${DESTDIR}/$${TARGET_MAC}-$${VERSION}.pkg"
} else {
_INSTALLER_CMD = "rm -rf $${DESTDIR}/temp && \
mkdir -p $${DESTDIR}/temp/ && \
cp -R $${DESTDIR}/$${TARGET_MAC}.app $${DESTDIR}/temp && \
pkgbuild --sign \'$$INSTALLER_SIGN_IDENTITY\' --root ${DESTDIR}/temp/ --component-plist resources/mac/installer.plist --install-location '/Applications/' $${DESTDIR}/$${TARGET_MAC}-$${VERSION}.pkg"
}
QMAKE_POST_LINK += $$quote( && codesign -s \'$$PACKAGE_SIGN_IDENTITY\' $${DESTDIR}/$${TARGET_MAC}.app \
--entitlements resources/mac/Entitlements.plist && \
$$_INSTALLER_CMD)
}
}
#
# Additional cleanup to be performed
#
win32 {
TARGET_DIR_WIN = $${DESTDIR}
QMAKE_CLEAN += $${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.exe \
$${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.dll \
$${TARGET_DIR_WIN}$${DIR_SEPARATOR}*.exe.bak
} else:macx {
QMAKE_CLEAN += -r $${DESTDIR}/*.app $${DESTDIR}/*.pkg $${DESTDIR}/*.dmg
} else {
QMAKE_CLEAN += -r $${DESTDIR}/*
}