script_BatchRenderer.bat

@echo off
chcp 65001
REM Include and process params
set SCRIPT_PATH=%~dp0
CALL "%SCRIPT_PATH%_config.bat" %1
set CONFIG_LOADED=True
IF "%OUTPUT_COMPILED_VIDEO_TO%"=="" (
	set OUTPUT_COMPILED_VIDEO_TO="%INPUT_FILE_PATH%"
)
cscript.exe "%SCRIPT_PATH%script_getRAM.vbs"
set AMOUNT_OF_RAM=%ERRORLEVEL%
cscript.exe "%SCRIPT_PATH%script_getAvailableRAM.vbs"
set AMOUNT_OF_AVAILABLE_RAM=%ERRORLEVEL%
cls

set PRESSET_TYPE=
set RENDER_TYPE=
set MODE_TYPE=""
set RENDER_MODE_TEXT=
FOR %%A IN (%*) DO (
    IF "%%A"=="P" (
		set RENDER_TYPE=Preset
		set PRESSET_TYPE=P
	)
    IF "%%A"=="RQ" (
		set RENDER_TYPE=Render Queue
		set PRESSET_TYPE=RQ
	)
    IF "%%A"=="noAudio" ( 
		set RENDER_MODE_TEXT=│ No Audio Mode!
		set MODE_TYPE=noAudio
	)
	IF "%%A"=="sequenceOnly" ( 
		set RENDER_MODE_TEXT=│ Sequence Only Mode!
		set MODE_TYPE=sequenceOnly
	)
)



IF "%RENDER_TYPE%"=="" (
	echo No Render Type was specified!
	pause
	EXIT /B %ERRORLEVEL%
)
cls


REM --------------------------------------------
REM 				   2021
REM					MADE BY ZLY
REM 			zlyswork@gmail.com
REM 		 https://twitter.com/zly_u
REM --------------------------------------------
title Multi-Threaded AE Render by Zly

echo       Multi-Threaded Render Setup for AE      
echo ----------------------------------------------
echo ''''''''''''''''''''''''''''''''''''''''''''''
echo.
echo.

echo ――――――――――――――――――――――――――――――――――――――――――――――
echo Render Type:       %RENDER_TYPE% %RENDER_MODE_TEXT%
IF "%PRESSET_TYPE%"=="P" (
	echo Comp name:         %COMP_NAME%
	echo Video RS template: %RS_TEMPLATE_VIDEO%
	echo Video OM template: %OM_TEMPLATE_VIDEO%
	echo Audio OM template: %OM_TEMPLATE_AUDIO%
) ELSE IF "%PRESSET_TYPE%"=="RQ" (
	echo RQ Video index:    %RENDER_QUEUE_INDEX_VIDEO%
	echo RQ Audio index:    %RENDER_QUEUE_INDEX_AUDIO%
)
echo ———―――――――――――――――――――――――――――――――――――――――――――
echo Amount of threads: %THREADS%
echo Amount of RAM:     %AMOUNT_OF_AVAILABLE_RAM%/%AMOUNT_OF_RAM%GB
echo Image Caching:     %IMAGE_CACHE_PERCENT%%% ┊ PER THREAD!
echo Memory Usage:      %MAX_MEMORY_PERCENT%%% ┊ PER THREAD!
echo ――――――――――――――――――――――――――――――――――――――――――――――
echo Input File:        %INPUT_FILE_NAME%
echo FPS:               %FPS%
echo Codec:	           %CODEC%
echo Output file name:  %OUTPUT_COMPILED_VIDEO_NAME%
echo Output to:         %OUTPUT_COMPILED_VIDEO_TO%
echo ――――――――――――――――――――――――――――――――――――――――――――――
echo.
echo.



IF "%INPUT_FILE%"=="" (
	echo Project File is required!
	pause
	EXIT /B %ERRORLEVEL%
) ELSE IF "%INPUT_FILE_EXT%" NEQ ".aep" (
	echo This is not an AE Project File!
	pause
	EXIT /B %ERRORLEVEL%
)


echo To start the render - press a key.
pause>nul
echo.


REM Render Images
FOR /l %%x in (1, 1, %THREADS%) DO (
	echo Executing process: %%x
	CALL :RenderSequence
)


echo.
REM Checking if any of the Render Processes running
CALL :CheckRenderPrcessesRunning "Rendering Sequence" %PATH_TO_AERENDER%
echo Sequence is rendered!
echo.


REM Render Audio
IF "%MODE_TYPE%" NEQ "noAudio" (
	IF "%MODE_TYPE%" NEQ "sequenceOnly" (
	
		CALL :RenderAudio
		CALL :CheckRenderPrcessesRunning "Rendering Audio" %PATH_TO_AERENDER%
		echo Audio is rendered!
		echo.
		
		set VideoStateCompiling=Compiling Video
	) ELSE (
		goto :audioSkip
	)
) ELSE (
	:audioSkip
	echo Audio is skipped!
	echo.
	
	set VideoStateCompiling=Compiling Video ┊ wo/ sound
)

REM Compile video
IF "%MODE_TYPE%" NEQ "sequenceOnly" (
	CALL :CompileVideo
	CALL :CheckRenderPrcessesRunning "%VideoStateCompiling%" %PATH_TO_FFMPEG%
	echo Video is compiled!
	echo.
) ELSE (
	echo Video is skipped!
	echo.
)

echo.
echo RENDER IS DONE!
echo.

echo Press any key to quit...
pause>nul
EXIT /B %ERRORLEVEL%



:RenderSequence
	IF "%PRESSET_TYPE%"=="P" (
		CALL "%SCRIPT_PATH%util_Render_Preset_sequence.bat" "%INPUT_FILE%"
	) ELSE (
		CALL "%SCRIPT_PATH%util_Render_RenderQueue_sequence.bat" "%INPUT_FILE%"
	)
EXIT /B 0

:RenderAudio
	IF "%PRESSET_TYPE%"=="P" (
		CALL "%SCRIPT_PATH%util_Render_Preset_audio.bat" "%INPUT_FILE%"
	) ELSE (
		CALL "%SCRIPT_PATH%util_Render_RenderQueue_audio.bat" "%INPUT_FILE%"
	)
EXIT /B 0

:CompileVideo
	IF "%MODE_TYPE%"=="noAudio" (
		CALL "%SCRIPT_PATH%util_compileVideo_NoAudio.bat"
	) ELSE (
		CALL "%SCRIPT_PATH%util_compileVideo_Full.bat"
	)
EXIT /B 0

:CheckRenderPrcessesRunning
	setlocal EnableDelayedExpansion
	set aStr=^│╱―╲
	set aStrLen=4
	set text=%1
	for /f %%a in ('copy /Z "%~f0" nul') do set "CR=%%a"
	:animationLoop
		<nul set /P "=!aStr:~%i%,1!!aStr:~%i%,1!!aStr:~%i%,1!!aStr:~%i%,1! !text:~1,-1! !aStr:~%i%,1!!aStr:~%i%,1!!aStr:~%i%,1!!aStr:~%i%,1!!CR!"
		set /a i+=1
		if %i%==%aStrLen% (set /a i=0)
		TIMEOUT /T 1 >nul 2>nul
		QPROCESS %2 >nul 2>nul
	if %ERRORLEVEL% EQU 0 goto animationLoop
	echo.
EXIT /B 0