build.gradle

plugins {
    id 'org.ajoberstar.grgit' version '5.0.0'
}

allprojects {
    apply plugin: 'java'

    sourceCompatibility = 11
    targetCompatibility = 11

    repositories {
        mavenLocal()
        maven {
            url 'https://github.com/MegaMek/mavenrepo/raw/master'
        }
        mavenCentral()
        maven {
            url 'https://jitpack.io'
        }
    }
}

subprojects {
    group = 'org.megamek'
    version = '0.49.20-SNAPSHOT'
}

ext {
    mmGitRoot = 'https://github.com/MegaMek/megamek.git'
    mmlGitRoot = 'https://github.com/MegaMek/megameklab.git'
    // Work on MML or MHQ sometimes requires changes in MM as well. The maven publishing tasks use
    // these properties to append the branch name to the artifact id if the repo is not in the master
    // branch, making it available separately to the child project.
    mmlBranch = grgit.branch.current().name
    mmlBranchTag = mmlBranch.equals('master') ? '' : '-' + mmlBranch

    // Allows setting a dependency on a different MM branch.
    mmBranch = 'master'
    mmBranchTag = mmBranch.equals('master') ? '' : '-' + mmBranch

    mmDir = "${rootDir}/../megamek"
}

// A properties_local.gradle file can be used to override any of the above options. For instance,
// rootProject.ext.mmlGitRoot = 'file:///path/to/local/repo' will cause the release target to clone a
// local copy of the repository rather than downloading it.

def localProperties = file('properties_local.gradle')

if (localProperties.exists()) {
    apply from: localProperties
}