build.gradle

/*
 * Wyvtils, a utility mod for 1.8.9.
 * Copyright (C) 2021 Wyvtils
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Lesser General Public License as published
 * by the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Lesser General Public License for more details.
 *
 * You should have received a copy of the GNU Lesser General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

plugins {
    id "com.github.gmazzo.buildconfig" version "3.0.1"
    id "org.jetbrains.kotlin.jvm" version "1.6.10"
    id "fabric-loom" version "0.10-SNAPSHOT"
    id "io.github.juuxel.loom-quiltflower-mini" version "1.1.0"
    id "java"
}

compileKotlin {
    kotlinOptions {
        jvmTarget = "17"
        freeCompilerArgs += "-Xopt-in=kotlin.RequiresOptIn"
    }
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17
archivesBaseName = project_name + "-1.18.1"
version = project_ver

buildConfig {
    className("WyvtilsInfo")
    packageName("net.wyvest.wyvtils")

    buildConfigField("String", "NAME", "\"${project_name}\"")
    buildConfigField("String", "VER", "\"${project_ver}\"")
    buildConfigField("String", "ID", "\"${project_id}\"")
}

loom {
    accessWidenerPath = file("src/main/resources/wyvtils.accesswidener")
    mixin {
        defaultRefmapName = "mixins.wyvtils.refmap.json"
    }
}

repositories {
    mavenCentral()
    maven {
        url = "https://repo.sk1er.club/repository/maven-public/"
    }
    maven {
        url = "https://repo.spongepowered.org/maven/"
    }
    maven {
        url = "https://jitpack.io/"
    }
    maven { url "https://maven.shedaniel.me/" }
    maven { url "https://maven.terraformersmc.com/releases/" }
}

dependencies {
    implementation("com.github.Wyvest:keventbus:e8e05ea")
    minecraft "com.mojang:minecraft:1.18.1"
    mappings "net.fabricmc:yarn:1.18.1+build.7:v2"
    modImplementation "net.fabricmc:fabric-loader:0.12.12"
    modImplementation "net.fabricmc.fabric-api:fabric-api:0.44.0+1.18"
    modImplementation("com.terraformersmc:modmenu:3.0.1") {
        transitive = false
    }
    modImplementation("gg.essential:essential-1.18-fabric:1680+release-1.1-phase1")
    modImplementation include("gg.essential:loader-fabric:1.0.0") {
        transitive = false
    }
    modImplementation("net.fabricmc:fabric-language-kotlin:1.7.1+kotlin.1.6.10")
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"

    it.options.release = 17
}

java {
    withSourcesJar()
}