build.gradle

plugins {
    id 'java'
    id 'scala'
    id 'application'
    id 'org.ajoberstar.grgit' version '4.1.1'
    id "io.gatling.gradle" version "3.6.1"
    id 'jacoco'
    id 'info.solidsoft.pitest' version '1.5.1'
}

group = 'conjob'
mainClassName = 'conjob.ConJobApplication'

dependencies {
    annotationProcessor 'org.projectlombok:lombok:1.18.10'

    compileOnly 'org.projectlombok:lombok:1.18.10'

    implementation 'io.dropwizard:dropwizard-core:2.1.6'
    implementation 'io.dropwizard:dropwizard-auth:2.1.6'

    implementation 'com.spotify:docker-client:8.16.0:shaded'
}

apply from: 'gradle/version.gradle'
apply from: 'gradle/unit-test.gradle'
apply from: 'gradle/integration-test.gradle'
apply from: 'gradle/acceptance-test.gradle'
apply from: 'gradle/performance-test.gradle'

repositories {
    mavenCentral()
}

task jacocoAllTestReport(type: JacocoReport) {
    getExecutionData().setFrom(fileTree(buildDir)
            .include("/jacoco/unitTest.exec")
            .include("/jacoco/integrationTest.exec")
            .include("/jacoco/run.exec"))
    sourceSets sourceSets.main
}

jacoco {
    applyTo run
}

task jacocoApplicationReport(type: JacocoReport) {
    executionData run
    sourceSets sourceSets.main
}