build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.0.5'
	id 'io.spring.dependency-management' version '1.1.0'

	id 'maven-publish'
}

bootJar {
	enabled = false
}

jar {
	enabled = true
	classifier ""
}

group = 'io.github.romanostrechlis'
version = '0.2-SNAPSHOT'
sourceCompatibility = '17'
targetCompatibility  = '17'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.kafka:spring-kafka'
	compileOnly 'org.projectlombok:lombok'
	developmentOnly 'org.springframework.boot:spring-boot-devtools'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.kafka:spring-kafka-test'
}

tasks.named('test') {
	useJUnitPlatform()
}

publishing {
	repositories {
		maven {
			name = "GitHubPackages"
			url = "https://maven.pkg.github.com/RomanosTrechlis/kafka-relay"
			credentials {
				username = project.findProperty("user") ?: System.getenv("USERNAME")
				password = project.findProperty("key") ?: System.getenv("TOKEN")
			}
		}
	}
	publications {
		gpr(MavenPublication) {
			pom {
				name = "kafka-relay"
				description = "Reads messages from a kafka cluster and forwards it to another kafka cluster"
				url = "https://github.com/RomanosTrechlis/kafka-relay"
				packaging = "jar"
			}
			artifact jar
		}
	}
}