qprogressindicatorspinning_mac.mm

/*
Copyright (C) 2011 by Mike McQuaid

Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:

The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.
*/

#include "qprogressindicatorspinning.h"

#include "qocoa_mac.h"

#import "Foundation/NSAutoreleasePool.h"
#import "AppKit/NSProgressIndicator.h"

class QProgressIndicatorSpinningPrivate : public QObject
{
public:
    QProgressIndicatorSpinningPrivate(QProgressIndicatorSpinning *qProgressIndicatorSpinning,
                                      NSProgressIndicator *nsProgressIndicator)
        : QObject(qProgressIndicatorSpinning), nsProgressIndicator(nsProgressIndicator) {}

    NSProgressIndicator *nsProgressIndicator;
};

QProgressIndicatorSpinning::QProgressIndicatorSpinning(QWidget *parent,
                                                       Thickness thickness)
    : QWidget(parent)
{
    NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];

    NSProgressIndicator *progress = [[NSProgressIndicator alloc] init];
    [progress setStyle:NSProgressIndicatorSpinningStyle];

    pimpl = new QProgressIndicatorSpinningPrivate(this, progress);

    setupLayout(progress, this);

    setFixedSize(thickness, thickness);

    [progress release];

    [pool drain];
}

void QProgressIndicatorSpinning::animate(bool animate)
{
    Q_ASSERT(pimpl);
    if (!pimpl)
        return;

    if (animate)
        [pimpl->nsProgressIndicator startAnimation:nil];
    else
        [pimpl->nsProgressIndicator stopAnimation:nil];
}