build.gradle

plugins {
    id 'java'
    id 'com.rikonardo.papermake' version '1.0.6'
    id 'com.gradleup.shadow' version '8.3.0'
}

group = 'al.yn'
version = '1.2.2'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
}

dependencies {
    compileOnly "io.papermc.paper:paper-api:1.21.1-R0.1-SNAPSHOT"

    implementation 'org.spongepowered:configurate-yaml:4.1.2'
    implementation 'org.spongepowered:configurate-gson:4.1.2'
}

def targetJavaVersion = 21

java {
    sourceCompatibility = JavaVersion.toVersion(targetJavaVersion)
    targetCompatibility = JavaVersion.toVersion(targetJavaVersion)
    toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
}

tasks.withType(JavaCompile).configureEach {
    options.release = targetJavaVersion
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching(['plugin.yml', 'paper-plugin.yml']) {
        expand props
    }
}

jar.dependsOn(shadowJar)

shadowJar {
    mergeServiceFiles()

    enableRelocation true
    relocationPrefix 'al.yn.simpleteleport.libs'
}