meet_tamara.txt

*set met_tamara true
*temp wotam "the woman"
"Are you here to slay the dragon?" says a voice, making you whirl around in surprise.

Before you, you see yet another woman, and how she managed to get so close to you without your hearing is a mystery. 

*label startchoice
*choice
	*disable_reuse #Look her over.
		*goto look
	#Put a hand on your weapon and tell her to step back.
		*goto handweapon
	#Guardedly ask what she wants.
		*goto guarded
	#Be friendly.
		*goto friendly
	
*label look
This woman is very different from the knight, for the knight was tall, perhaps close to six feet, and everything about her positively glittered. This woman stands perhaps five feet six inches, slender but muscular, and dressed in earth-tones, she looks as if she could easily fade into the underbrush and disappear. 

She's wearing tan, skin-tight leather breeches that do well to show off her figure. Her boots are knee-high, fashioned from expensive leather, and she seems to have a custom-made leather vest inlaid with an intricate pattern in silver and a beautiful deep red color. It must've cost a fortune, but it's also practical, affording more than a small amount of protection in battle.

Her breasts are a small, shapely pair, showing just a hint of cleavage in the vest's neckline. Her arms are bare, but she's wearing doe-skin gloves that go up to her elbows.

She has a backpack and belt pouch, and by her side is a slender, wicked-looking sword. A crossbow is draped over her back with quarrels at the ready.

Her hair's a deep reddish-brown and falls to her shoulders. Her eyes are a piercing green, and when she looks at you, her intensity makes you nervous. You don't know if she's going to snap at you or simply turn away in disdain.
*goto startchoice

*label handweapon
"Go ahead and draw," the woman says. "I could've killed you already." She taps the crossbow on her back.

"Besides," she goes on. "I'm not in sword range, so I shouldn't have to step back. This is normal talking range."
*choice
	#Draw!
		*goto draw
	#Ask her what she wants.
		*goto guarded
	
*label draw
As soon as you begin to draw, the woman leaps backwards into a back handspring that takes her even further out of range. She draws her weapon, a wicked-looking scimitar.

"I just wanted to talk, but if you want to fight, bring it," she says.
*choice
	#Tell her you're willing to talk, just didn't feel safe after she snuck so close to you.
		*goto willingsafe
	#Attack.
		*goto attack
	
*label willingsafe
*set tamara_respect %+20
"Fair enough," the woman says. "Now, am I right to assume you're here to slay the dragon?"
*choice
	#"I'm here to rescue the princess."
		*goto tellrescue
	#"My reasons are my own."
		*goto ownreasons

*label attack
*set tamara_enemy true
*set with_tamara false
*set know_tamaras_name true
The woman stands her ground as you advance upon her and meets your attack sword to sword. You find that she's a skilled fighter, and though you're stronger and have the reach advantage, her speed makes her an even match for you. The duel could go either way.

"You're a better swordsman than you look," the woman laughs. "You might even be better than I am." She continues to fence with you, unconcerned.

"Shouldn't you be more worried?" you ask.

"I would be, except..." 

She makes an especially strong attack which puts you on the defensive for a split-second, and then she springs backwards.

"I'm a thief," she says, "Not a warrior. Sleep with one eye open tonight."

She bounds off into the forest, and you know you won't be able to catch her.

"The name's Tamara, by the way," her voice comes from somewhere beyond the veil of leaves, and then, silence. She's gone.
*choice
	#Try to find her.
		*goto tryfind
	#Call out to her.
		*goto callout
	#Continue your journey.
		*goto continue
	
*label tryfind
*temp numlooks 0
*temp killedsquirrel false
You hurry forward in the direction she ran, but there's no sign of her. It's like she just disappeared!

On one hand, it might be good to find her, but you also worry about leaving your possessions at your campsite for too long. Your whole backpack is there with all your food, water, and gear. All you have on you is your sword and armor.
*choice
	#Keep looking for her.
		You charge through the underbrush, dodging around trees, always ready for an ambush. You go a good long way before you start to realize you might have trouble finding your way back to your campsite, for this part of the forest lacks good landmarks. 
		*choice
			#Keep looking for Tamara.
				*goto keeplooking
			#Return to your campsite.
				*goto lost
	#Return to your campsite.
		You find nothing amiss at last night's camp.

		*goto continue

*label keeplooking
*set numlooks +1
*if numlooks = 1
	There's still no sign of Tamara. 
	*goto keeplookingchoice
*elseif numlooks = 2
	There's still no sign of Tamara, and now finding your way back to your campsite will be even more difficult.
	*goto keeplookingchoice
*elseif numlooks = 3
	You find no sign of Tamara. However, you found some edible mushrooms.
	
	[boldblue]Rations increase by half a ration.[/boldblue]
	*set food + 0.5
	*script updateStatBar();
	*goto keeplookingchoice
*elseif numlooks = 4
	There's still no sign of Tamara, and you're getting a bit worried about your gear left behind at your campsite.
	*goto keeplookingchoice
*elseif numlooks = 5
	You find no sign of Tamara. 
	*goto squirrel
*elseif numlooks = 6
	*goto parley
*label keeplookingchoice
*choice
	#Keep looking for Tamara.
		*goto keeplooking
	#Return to your campsite.
		*goto lost

*label squirrel
However, you see a nice, fat squirrel, which would help replenish your dwindling food supply. On the other hand, it's a delay as well as a distraction, and you're pretty sure you have enough food to last until you reach the dragon's lair. It will run out shortly after, however, assuming you survive, and if the princess is with you, she will need food as well.
*choice
	#Throw a stick at it.
		*set killedsquirrel true
		*set has_squirrel true
		Nailed it!

		[boldblue]Rations increase by one.[/boldblue]
		*set food +1
		*script updateStatBar();
		*goto keeplookingchoice
	#Ignore it and keep looking for Tamara.
		*goto keeplooking

*label lost
[This option is yet to be written.]

*label parley
You continue moving in the direction Tamara ran.
*page_break
*if killedsquirrel
	"Nice catch," you hear a familiar female voice say. It's Tamara who has managed to sneak up on you once again, and she's pointing at the squirrel you're carrying. She's standing out of sword range at a respectful distance this time.
	*choice
		#Ask her what she wants.
			*goto whatwants
		#Draw your sword.
			*goto squirreldraw
*else
	"Hey," says a familiar female voice. It's Tamara who has managed to sneak up on you once again, though this time she's at a more respectful distance well out of sword-range.

	She tosses a dead squirrel at your feet, and it looks very much like the one you just saw.

	"Peace offering," she says. 
	*choice
		#Pick up the squirrel.
			*set has_squirrel true
			*set food +1
			*script updateStatBar();
			"See, I'm useful," Tamara says. "We've gotten off to a bad start, but I meant to make you a proposal. Tell me, why are you here?"
			*goto reasonschoice
		#Draw your sword.
			*goto squirreldraw

*label whatwants
"I still want the same thing as before you attacked me," Tamara says. "I have a proposition for you. Tell me, why are you here?"
*goto reasonschoice

*label squirreldraw
"Not this again," Tamara groans. "Look, I like swordfighting as much as the next guy, but we can play around later. I have a proposition for you, so will you hear me out?"
*choice
	#"I'm listening."
		"Okay, look," Tamara says. "I'm here to steal as much of the dragon's hoard as I can, and some bumbling idiot blundering in at the same time might mess things up for both of us. Make sense? So tell me, why are you here?"
		*goto reasonschoice
	#Attack.
		"OOOOH! You're impossible!" Tamara spats, backpedaling to stay out of range.

		As she turns to run, she calls out, "Have fun trying to make it back to your campsite before I get there and pilfer everything!"


*label lostwithtamara
Tamara shrugs. "Okay, then," is all she says and stands around as if waiting.
*choice
	#Head back to camp.
		*goto headcamp
	#Realize it'd be faster if Tamara helps you find your camp. 
		*goto tamarafindcamp

*label headcamp
You start heading back toward your camp, despite having only a vague notion of its general direction, and Tamara begins trailing along behind you at a distance of about forty feet. Each time you glance back, she looks around as if enjoying the scenery, but slowly, she gains on you. Eventually, she's around twenty feet to one side of you, then overtakes you. 
*choice
	#Try to keep up with her.
		*goto keepup
	#Let her go.
		*goto letgo

*label keepup
[This option is yet to be written.]

*label letgo
Tamara sees you falling further behind and says, "Are you sure you want a thief to find her way back to your campsite ahead of you?"

That would be a bad idea...
*fake_choice
	#Try to keep up.
Tamara sees you trying to keep up and seems to slow her pace. 
*choice
	#Stay twenty feet back.
		*goto 20back
	#Catch up with her.
		*goto catchup

*label 20back
Just as you begin to suspect you're close to your campsite, Tamara says, "Your camp is just up ahead," cackles, and races ahead, quickly disappearing from view. Nooooo... your stuff!
*choice
	#Chase after her!
		*goto chase
	#Go cautiously. It might be a trap.
		*goto cautious

*label chase
You're fast, but Tamara's faster. By the time you reach your campsite, Tamara's already buried your fire's ashes and removed all sign that someone spent the night there. Your pack is sitting where you left it, apparently unmolested.

"Well, let's get going," Tamara says.
*choice
	#Grab your pack and join her.
		Tamara watches as you fall in step with her.

		"So... we ARE traveling together now, right?" she asks.
		*goto grudgeagreejoin
	#Inspect your pack to see if anything's missing.
		Tamara sees you inspecting your pack and says, "Oh, come on! I want us to join forces, so why would I steal from you? I was just joking around before."
		*choice
			#Tell her you are very amused.
				"See, I'm a fun girl to have around. We're joining forces, right?"
				*choice
					#Agree
						*gosub_scene agreement
						*goto thepath
					#Refuse to join forces.
						*comment [start here]. Below is a TEMP goto
						[This option is yet to be written.]


						*goto thepath


*label cautious
[This option is yet to be written.]

*label catchup
"Hi," Tamara says when you fall in step with her. 
*goto tamarafindcamp2

*label tamarafindcamp
"This way," Tamara says and begins moving in the general direction of your camp. 
*label tamarafindcamp2
As you walk, she points out different ways you can keep track of where you are in a forest, and by the time you arrive back at your camp, you feel like you learned a lot. You start to gether your belongings.

"See, I'm useful," Tamara says. "We're traveling together now, right?"
*label grudgeagreejoin
*fake_choice
	#"I guess..."
*gosub_scene agreement
*goto thepath

*label callout
Only silence answers your call. You have no choice but to continue your journey.

*goto continue

*label continue
You gather your belongings, extinguish the campfire, and resume walking along the path that leads toward the dragon's lair.

You walk for awhile, always wondering if Tamara's not trailing you just out of sight. You turn around from time to time but see nothing.

*goto_scene chardell_alone

*label guarded
"Like I just asked," the woman says. "I want to know what you're doing here. I'm here to plunder the dragon's hoard, and a stupid adventurer bumbling in could get me killed. Is that why you're here?"
*choice
	#"I'm here to rescue the princess."
		*goto tellrescue
	#"My reasons are my own."
		*goto ownreasons
	
*label friendly
"Oh, hello," you say. "Fancy meeting you out here in the middle of nowhere. May I ask what you are doing so far from civilization and so near to the dragon's lair?"

"You can ask," the woman responds, not returning your friendliness but not hostile either. "The dragon's lair is exactly why I'm here. What of yourself?"
*label reasonschoice
*if know_tamaras_name
	*set wotam "Tamara"
*choice
	#"I'm here to rescue the princess."
		*goto tellrescue
	#"My reasons are my own."
		*goto ownreasons
	
*label tellrescue
"How noble of you," ${wotam} says. "Do you expect me to be impressed?"

*label disdain
She looks you up and down disdainfully.

"Well, at least you have a rope, so you must know the climb is difficult. However, do you know that the dragon can hear each stroke of your hammer when you're pounding in your mountain-climbing stakes? Do you know how it's watching all the time, and even now, from so far away, through tons of rock, it can probably sense us to at least some extent?"

*goto reverie

*label ownreasons
"Are they now?" ${wotam} smirks. "Not really. No one comes here but for the dragon, so I can safely assume that's why you're here." 

*goto disdain

*label reverie
In the days following the dragon sighting, you attempted to garner aid, both in the form of companions and information, to help you on your quest, but very little was forthcoming. Everyone with whom you spoke told you were crazy, and almost none had any helpful information. A ranger told you about the mountain and the need for ropes to climb it, and though he taught you the rudiments of mountain climbing, he too attempted to dissuade you from your quest. So far, even the most skilled knights have not been able to best this particular dragon.

You heard it's a very old one, has roosted in DragonKeep for as long as anyone can remember, and over time, the kings learned that they could appease the dragon by offering it maidens, gold, and jewels. Each spring, a maiden and a large chest of treasure is brought to a special place for the dragon to collect, and this has reduced but not eliminated its depredations of the countryside.

Continue your reverie?
*choice
	#Yes.
		*goto continuereverie
	#No.
		*goto ceasereverie

*label continuereverie
Because of this evil pact, the royal court felt secure, so it was a great horror when the dragon attacked the capital city itself, for that had not happened since the very first offering, 150 years ago.

It was surmised (by the sages who studied dragonlore) that the dragon was incensed by the audacity of the princess's high tower, a magnificent structure twice as tall as any ever built before. 

A tradition had developed in Zhan where the higher a lady's bower, the more desired she was purported to be, and thus all ladies, when the became of age, lived in the highest one their family could afford to build. The princesses had the highest of all, and the king, who loved this particular daughter to an unusually great extent, undertook the task of building an impossibly tall tower to match her peerless beauty--and in so doing, unintentionally brought about the greatest tragedy the kingdom had ever known.

Such is the price of arrogance... a warning that you too, it could be said, have not heeded.

*goto ceasereverie

*label ceasereverie
So, what is your answer to ${wotam}'s question? Did you know that dragons can sense things around their lair?
*choice
	#"No," you admit.
		*goto honestignorance
	#"Of course, I do," you lie.
		*goto lieignorance
	
*label honestignorance
*set learned_dragon_sense true
*set honest_ignorance true
"Well, you may be a fool, but at least you're an honest fool," ${wotam} says. "They can. Sounds. Smells. Their senses are extraordinarily powerful, but they also extend into the psychic realm. They can sense magic, so if you're carrying any magic items, they will give you away once you're close. They can also sense our very emotions, but only the negative ones. Greed. Anger. Jealousy. These a dragon can sense even miles away."

She pauses as if mulling something over.

*label ignorance2
*if not(know_tamaras_name)
	*set know_tamaras_name true
	"My name's Tamara," she says finally, "And unlike you, I have no silly notions about rescuing the princess. I'm here for the treasure plain and simple. I'm a thief, master-class, my quest under sanction by the thieves guild, for imagine the glory--the thief who robbed a dragon!"
	*goto ignorance3
*else
	"Well, I have no silly notions about rescuing the princess. I'm here for the treasure plain and simple. I'm a thief, master-class, my quest under sanction by the thieves guild, for imagine the glory--the thief who robbed a dragon!"
*label ignorance3

Speaking thusly, she raises a clenched fist mightily before her and gazes purposefully off into the distance in imitation of a knight in victory. She smiles sheepishly at her own overenthusiasm and then continues, "I, in the noble tradition of thieves everywhere, plan to sneak in, and I know the location of the hidden entrance. I can't have you alerting the dragon to our presence, so I propose we work together. I will get you in without the dragon knowing, but after that, you're on your own. I steal the treasure, and you, if you're truly serious about your silly quest, can go rescue the princess, if she's even still alive. Is it a deal?"

*if honest_ignorance
	*set tamara_respect %+10
	Tamara's respect for you rises slightly:
	*stat_chart
		percent tamara_respect Tamara's Respect
*choice
	#"Okay, deal."
		*goto agree
	#"Okay, but do you think you could stop insulting me all the time?"
		*goto caveats
	#"No deal."
		*goto nodeal
	
*label agree
*gosub_scene agreement
	
*label thepath
"Well, you already know my name," Tamara says. "What's yours?"

*gosub_scene intro

"Ok, come on then," Tamara says without so much as a handshake.

The two of you continue to walk down the path together in silence for a good bit. 

*goto_scene chardell

*label caveats
*set tamara_respect %+5
Tamara's respect for you rises very slightly:
*stat_chart
	percent tamara_respect Tamara's Respect
*line_break
"Yes," Tamara says. "I will certainly stop 'insulting you,' because I never have. Speaking honestly, that's another matter." She laughs. "Well, I'm glad we have a deal. Right? We have a deal?"
*fake_choice
	#Right.
*gosub_scene agreement

*goto thepath

*label nodeal
Tamara exhales loudly in frustration. "Look," she says, "You're going to get yourself killed, and while I normally laugh at fools getting their comeupance, in this case, your blunder will interfere with my plans. Only the gods know why, but I'm offering to help you. If you refuse, you will have to wait until I'm finished before making your own approach, but I don't trust you enough for that. You might race ahead or do some other stupid thing to get me killed. Unless we work together, I'll have to kill you, but that would alert the dragon. There's no choice. We MUST agree to work together. Now, IS IT A DEAL?"

*choice
	#"Okay, deal."
		*goto agree
	#Propose that you go first. That'll distract the dragon and make it easier for Tamara to steal the treasure.
		*goto proposal
	#"No deal." You're tired of Tamara's nonsense and walk off.
		*goto walkoff
	
*label proposal
"Okay, fine," Tamara says. "You can go first if you want. That also works if that's what you really want to do."

She looks at you and waits.

"Well? Go on then. Go rescue your princess."

*choice
	#Continue your quest.
		*goto continuequest
	#Change your mind and agree to work together.
		*goto agree
	
*label continuequest
Tamara shrugs. "Fool," you hear her say just before losing sight of her among the trees.

*label walk
You walk for awhile, always wondering if Tamara's not trailing you just out of sight. You turn around from time to time but see nothing.

*goto_scene chardell_alone

*label walkoff
Surprisingly, Tamara doesn't protest, and the last you see of her is her shaking her head at your foolishness.

*goto walk

*label lieignorance
"Yeah?" the woman says, her eyes narrowing suspiciously. "Well, then, do you know that it can smell you from a hundred yards off?"
*choice
	#Admit you didn't know that.
		*goto ignorance
	#Lie and say you knew that too.
		*goto lie2
	
*label ignorance
"As you can see," the woman says, "I have done my preparations. There are other things I know too, secrets greater even than these." 

*label pause
She pauses for a moment, and you wonder if she's going to tell you more. Instead, she looks at you a moment as if coming to a decision.

*goto ignorance2

*label lie2
"Then I hope you've brought something to mask your scent," the woman says, and you frantically start to think what you have that might work.

If she's noticed the consernation she's caused, she shows no sign.

"Do you know that they can sense our very emotions, but only bad ones?" she asks, continuing her grilling of you.

*choice
	#Admit you didn't know that.
		*goto ignorance
	#Lie and say you knew that too.
		*goto lie3
	#Ask how she knows all this stuff.
		*goto howknows

*label lie3
"I'm sure you do," the woman says, but it's obvious she doesn't believe you. 

"Do you know this dragon's name?"

*choice
	#Claim you do.
		*goto dragonname
	#Admit you don't know it.
		*achieve dragonname
		"It's Myrristicor," the woman says dramatically. "I might be the only one who's not a sage who knows that."
		
		She smiles proudly but then feels vulnerable and shrugs instead.
		
		*goto ignorance

*label howknows
"How did YOU learn all this stuff?" she asks, turning the tables.

You hesitate, trying to think of how to answer, and she laughs. 

"I know you don't really know all this stuff," she smiles. "Suffice it to say, I've done my preparations."

*goto pause

*label dragonname
"What is it, then?" the woman asks.

*choice
	#"I can't say. It's a secret."
		*goto secretname
	#Admit you don't know.
		*goto ignorance
	
*label secretname
"Of course it is," the woman says. "I can't tell you what it is either. Well, since you know that secret, do you know the dragon's secret weakness?"

*choice
	#Claim you do.
		*goto weakness
	#Admit you don't know.
		*goto noweakness
	
*label weakness
"Then I don't have to tell you what it is, do I?" the woman says and winks. "Look, I can tell when someone's lying. I know a lot more secrets than these."

*goto pause

*label noweakness
*achieve weakness
"I don't know its secret weakness either. Was hoping you could tell me," the woman laughs.

*goto pause