build.gradle

plugins {
	id "java"
	id "eclipse"
	id "idea"
	id "fabric-loom" version "0.5-SNAPSHOT"
	id "maven-publish"
	id "com.jfrog.artifactory" version "4.9.0"
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

if(rootProject.file("private.gradle").exists()) { //Publishing details
	apply from: "private.gradle"
}

archivesBaseName = "${project.archives_base_name}"
group = "${project.maven_group}"
version = "${project.mod_version}+${project.minecraft_version}"

minecraft {
}

repositories {
	mavenCentral()
	maven { url "http://maven.fabricmc.net/" } // Fabric maven - home of Fabric API and ModMenu
	maven { url "https://server.bbkr.space/artifactory/libs-release" } // Cotton maven - home of Cotton projects
	maven { url "https://dl.bintray.com/ladysnake/libs" } // Onyx Studios maven - home of Cardinal Components
	maven { url "https://alexiil.uk/maven/" } // Alexiil's maven - home of Lib Block Attributes
	maven { url "https://maven.dblsaiko.net/" } //Grondag's maven - home of Fluidity
	maven { url "https://jitpack.io" }
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.minecraft_version}+build.${project.yarn_build}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
	compileOnly "com.google.code.findbugs:jsr305:3.0.2"

	//cardinal components
	include modImplementation("io.github.onyxstudios.Cardinal-Components-API:cardinal-components-base:${project.cardinal_version}") //only non-fabricmc lib we actually require at runtime
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-block:${project.cardinal_version}"
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-item:${project.cardinal_version}"
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-entity:${project.cardinal_version}"
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-chunk:${project.cardinal_version}"
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-world:${project.cardinal_version}"
	modCompileOnly "io.github.onyxstudios.Cardinal-Components-API:cardinal-components-level:${project.cardinal_version}"

	//lib block attributes
	modCompileOnly "alexiil.mc.lib:libblockattributes-all:${project.lba_version}"

	//fluidity
	modCompileOnly("grondag:fluidity-mc116:${project.fluidity_version}.+") { transitive = false }

	//item inventory
	modCompileOnly "com.github.emilyploszaj:item-inventory:${project.item_inventory_version}"

	//techreborn energy
	modCompileOnly "teamreborn:energy:${tr_energy_version}"
}

processResources {
	inputs.property "version", project.version
	from(sourceSets.main.resources.srcDirs) {
		include "fabric.mod.json"
		expand version: project.version
	}
	from(sourceSets.main.resources.srcDirs) {
		exclude "fabric.mod.json"
	}
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
	options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
	classifier = "sources"
	from sourceSets.main.allSource
}

jar {
	from "LICENSE"
}

// configure the maven publication
publishing {
	publications {
		maven(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			//artifact(jar) {
			//	builtBy remapJar
			//}
			artifact ("${project.buildDir.absolutePath}/libs/${archivesBaseName}-${project.version}.jar") { //release jar - file location not provided anywhere in loom
				classifier null
				builtBy remapJar
			}

			artifact ("${project.buildDir.absolutePath}/libs/${archivesBaseName}-${project.version}-dev.jar") { //release jar - file location not provided anywhere in loom
				classifier "dev"
				builtBy remapJar
			}

			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// select the repositories you want to publish to
	repositories {
		// uncomment to publish to the local maven
		// mavenLocal()
	}
}

artifactory {
	if (project.hasProperty("artifactoryUsername")) {
		contextUrl = "https://server.bbkr.space/artifactory/"
		publish {
			repository {
				if (version.contains("SNAPSHOT")) {
					repoKey = "libs-snapshot"
				} else {
					repoKey = "libs-release"
				}

				username = artifactoryUsername
				password = artifactoryPassword
			}
			defaults {
				publications("maven")

				publishArtifacts = true
				publishPom = true
			}
		}
	} else {
		println "Cannot configure artifactory; please define ext.artifactoryUsername and ext.artifactoryPassword before running artifactoryPublish"
	}
}