forked from tweag/jupyenv
-
Notifications
You must be signed in to change notification settings - Fork 0
/
python-overlay.nix
199 lines (158 loc) · 5.32 KB
/
python-overlay.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
_: pkgs:
let
packageOverrides = selfPythonPackages: pythonPackages: {
jupyter_contrib_core = pythonPackages.buildPythonPackage rec {
pname = "jupyter_contrib_core";
version = "0.3.3";
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "e65bc0e932ff31801003cef160a4665f2812efe26a53801925a634735e9a5794";
};
doCheck = false; # too much
propagatedBuildInputs = [
pythonPackages.traitlets
pythonPackages.notebook
pythonPackages.tornado
];
};
jupyter_nbextensions_configurator = pythonPackages.buildPythonPackage rec {
pname = "jupyter_nbextensions_configurator";
version = "0.4.1";
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "e5e86b5d9d898e1ffb30ebb08e4ad8696999f798fef3ff3262d7b999076e4e83";
};
propagatedBuildInputs = [
selfPythonPackages.jupyter_contrib_core
pythonPackages.pyyaml
];
doCheck = false; # too much
};
umaplearn = pythonPackages.buildPythonPackage rec {
pname = "umap-learn";
version = "0.3.7";
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "9c81c9cdc46cc8a87adf1972eeac5ec69bbe9cec440c0e4995fc68a015aafeb9";
};
propagatedBuildInputs = with pythonPackages; [
numpy
scipy
numba
scikitlearn
];
doCheck = false; # too much
};
jupyter_c_kernel = pythonPackages.buildPythonPackage rec {
pname = "jupyter_c_kernel";
version = "1.2.2";
doCheck = false;
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "e4b34235b42761cfc3ff08386675b2362e5a97fb926c135eee782661db08a140";
};
meta = with pkgs.stdenv.lib; {
description = "Minimalistic C kernel for Jupyter";
homepage = https://github.com/brendanrius/jupyter-c-kernel/;
license = licenses.mit;
maintainers = [];
};
};
ansible-kernel = pythonPackages.buildPythonPackage rec {
pname = "ansible-kernel";
version = "0.9.0";
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "0dkncg2chv562i2fg47ic6p2h8rz739jlvii6m24y3scfahkk455";
};
propagatedBuildInputs = [
pythonPackages.ipywidgets
pythonPackages.six
pythonPackages.docopt
pythonPackages.tqdm
pythonPackages.jupyter
pythonPackages.psutil
pythonPackages.pyyaml
selfPythonPackages.ansible
selfPythonPackages.ansible-runner
];
postPatch = ''
touch LICENSE.md
# remove custom install
sed -i "s/cmdclass={'install': Installer},//" setup.py
'';
doCheck = false;
meta = with pkgs.stdenv.lib; {
description = "An Ansible kernel for Jupyter";
homepage = https://github.com/ansible/ansible-jupyter-kernel;
license = licenses.asl20;
};
};
ansible-runner = pythonPackages.buildPythonPackage rec {
pname = "ansible-runner";
version = "1.1.2";
src = pythonPackages.fetchPypi {
inherit pname version;
sha256 = "2376b39c7b4749e17e15a21844e37164d6df964c9f35f27aa679c0707b1f7b19";
};
checkInputs = [ pythonPackages.pytest pythonPackages.mock pythonPackages.python ];
propagatedBuildInputs = [
pythonPackages.six
pythonPackages.pyyaml
pythonPackages.python-daemon
pythonPackages.pexpect
pythonPackages.psutil
];
checkPhase = ''
pytest test
'';
# tests fail due to python location during test
doCheck = false;
meta = with pkgs.stdenv.lib; {
description = "Stable and consistent interface abstraction to Ansible";
homepage = https://github.com/ansible/ansible-runner;
license = licenses.asl20;
};
};
ansible = pythonPackages.buildPythonPackage rec {
pname = "ansible";
version = "2.7.5";
outputs = [ "out" "man" ];
src = pkgs.fetchurl {
url = "https://releases.ansible.com/ansible/${pname}-${version}.tar.gz";
sha256 = "1fsif2jmkrrgiawsd8r6sxrqvh01fvrmdhas0p540a6i9fby3yda";
};
prePatch = ''
sed -i "s,/usr/,$out," lib/ansible/constants.py
'';
postInstall = ''
wrapPythonProgramsIn "$out/bin" "$out $PYTHONPATH"
for m in docs/man/man1/*; do
install -vD $m -t $man/share/man/man1
done
'';
doCheck = false;
dontStrip = true;
dontPatchELF = true;
dontPatchShebangs = false;
propagatedBuildInputs = with pythonPackages; [
pycrypto paramiko jinja2 pyyaml httplib2 boto six netaddr dnspython jmespath dopy
];
meta = with pkgs.stdenv.lib; {
homepage = http://www.ansible.com;
description = "A simple automation tool";
license = with licenses; [ gpl3 ];
};
};
rsa = pythonPackages.rsa.overridePythonAttrs (oldAttrs: {
preConfigure = ''
substituteInPlace setup.py --replace "open('README.md')" "open('README.md',encoding='utf-8')"
'';
});
# Performance tests failing on different computers
pathpy = pythonPackages.pathpy.overridePythonAttrs (_:{
doCheck = false;
});
};
in
{ python3 = pkgs.python3.override { inherit packageOverrides; }; }